Dynamic Variables and Eval

#1 I think the reason you got the first one not working is because

if ($obj.$property $= "$value")

Should be something like this

if ($obj.property $= $value)

Basically, I think you got the term confuse with "$value" and $value are the same which aren't.


Aun.

#2 @Deozaan
I think you shouldn't eval an "if" statement alone (I never tried but it seems like a wrong thing to do).

#3 @Aun

You're right, they are completely different from each other.

if (1578.Team $= "Killers")
if (1578.Team $= Killers)

Are two separate things. To be honest I'm not sure which is correct but I figure that a String Compare would require a string, and without quotation marks it's not a string, but the name of an object.

In either case, though, this is not the problem. I actually added the quotes after the parse error because of like I just said, I think a string would require quotes.

@Benjamin

So what would you suggest? If I put the continue statement in the eval, it doesn't realize it's in a loop and ignores it, but apparently by using the eval statement TGB doesn't realize it's an IF statement that needs to have an open or close.

Ooh, how about this?

$obj = 1578;
$property = "Team";
$value = "Killers";

$str = $obj @ "." @ $property; // $obj.$property, or in this example 1578.Team

if (eval($str) !$= $value)
    continue;

#4 Okay I got it working with the following code:

for( %i = 0; %i < %count; %i++ )
   {
      %sceneObject = %scenegraph.getSceneObject( %i );
      %sceneObjTest = "if(" @ %sceneObject @ "." @ %type @ " $= " @ %value @ ") " @ %this @ ".targetList.add(" @ %sceneObject @ ".getID());";
      // if (%sceneObject.%type $= %value) %this.targetList.add(%sceneObject.getID());
      eval(%sceneObjTest);
   }

Thanks for the helping me think about it another way.

#5 Maybe I'm missing a nuance, but couldn't you just use getFieldValue?

if ( %sceneObject.getFieldValue(%type) $= %value ) 
    %this.targetList.add(%sceneObject.getID());

#6 Heh heh. I could but then I'd have to know about it in the first place. (c:

Thanks Andy, that knowledge will make things a lot easier in the future!

#7 No problem - I realize there are hundreds of console functions/methods - it takes a while!

I would suggest taking a bit of time to look through console/simBase.cc and console/consoleFunctions.cc for ConsoleFunctions and ConsoleMethods - it'll probably help out a lot in the future

#8 Don't forget the power of TorqueScript arrays---you can use strings as indexes!

$obj.properties["Team"] = "Killers";
$obj.properties["SomeOtherIndex"] = "Foo";

$value = "Team";

$str = $obj.properties[$value];

echo($str);

--> Killers

#9 Thanks for the suggestions/reminders. Very useful!

#10 Sorry for reviving this old thread, but once again I have some questions about how to work with some dynamic variables.

Can the arrays "stack"?

For example, are any of the following examples valid?

$obj.properties[%i].name = "Bob";

$obj.properties[%i]["X"] = 42;

$obj.properties["grid" @ %x @ %y] = true;

Thanks in advance for any help.

#11 Examples 1 and 3 are valid. Example 2 would probably give an error, but I'm not 100% sure without trying it.

#12 Example 1 is valid only if there is an object assigned to the %obj.properties[%i], if you just use:

%obj = new SimObject();
%obj.properties[0].name = "Bob";
echo(%obj.properties[0].name);

it will echo empty line, as the TS trying to assign "Bob" to the "name" field of object assigned to %obj.properties[%i].
The valid options:

%obj.properties[%i, "name"] = "Bob";

or:

%obj = new SimObject();
%obj2 = new SimObject();
%obj.properties[0] = %obj2;
%obj.properties[0].name = "Bob";
echo(%obj.properties[0].name);
echo(%obj2.name);

This will work. Your second example should be written in the same manner:

%obj.properties[%i, "x"] = 42;

to work, or it will give you "Parse error".

The third is correct, but you can mess up with values if your %x and %y is going to be numbers > 10.
Example:

%x = 12;
%y = 1;
%obj.properties["grid" @ %x @ %y] = true;
echo(%obj.properties["grid" @ %x @ %y]); // Will output "1" (true)
%a = 1;
%b = 21;
%obj.properties["grid" @ %a @ %b] = false; // Notice the different value assignment!
echo(%obj.properties["grid" @ %a @ %b]); // Will output "0" (false)
echo(%obj.properties["grid" @ %x @ %y]); // Will output "0" (false), not "1" (true) as assumed.

This because your are building:
%obj.properties[ "grid" @ 12 @ 1 ] and it's equal to "grid121".
On second "attempt":
%obj.properties[ "grid" @ 1 @ 21 ] and it's equal to "grid121" too and by second assignment we overwriting the previously assigned value.
if you use comma to separate values:
%obj.properties["grid", %x, %y] it will build you to:
%obj.propertiesgrid_12_1 and %obj.propertiesgrid_1_21
(using 12, 1 and 1, 21 respectively)
This is something like dynamic pseudo-array, very flexible, love this feature in TorqueScript :)

Hope this helps!

#13 Yes that's very helpful! Thank you!