My projectile doesn't arc correctly

datablock t2dSceneObjectDatablock( MolotovProjectileData : ProjectileBaseData )
{
    Class             = "MolotovProjectile";
    AnimationName     = "redFishAnimation";

    CollisionCallback      = true;
    CollisionDetectionMode = "PLATFORM_CIRCLE";
    CollisionCircleScale   = 0.2;

    Lifetime          = 10.0;
    Size              = "12.000 10.000";
    
    ProjectileDamage  = 12;
};

new ScriptObject( MolotovLauncherAction : ProjectileBaseAction )
{
    ProjectileType   = "t2dAnimatedSprite";
    ProjectileConfig = MolotovProjectileData;
    ProjectileSpeed  = 70;
    ProjectileOffset = 1;
    ProjectileArc    = 0;

    CoolDown         = 500;
    Continuous       = false;

    Burst            = false;
    BurstCount       = 3;
    BurstDelay       = 30;

    //TriggerSound     = RocketLauncherFireSound;
};

//-----------------------------------------------------------------------------

new ScriptObject( MolotovLauncherWeapon : WeaponBase )
{
    // Action
    ActionCount = 1;
    Action[0]   = MolotovLauncherAction;
};

//-----------------------------------------------------------------------------

function MolotovProjectile::onAddToScene( %this )
{
   %this.LinearVelocity.Y = -100;
   %this.setConstantForce( 0 SPC 200, true );
}

function MolotovProjectile::onRemove( %this )
{
    // Create Impact Animation.
    %impactEffect = new t2dAnimatedSprite()
    {
        SceneGraph    = %this.getSceneGraph();
        Class         = "MolotovImpactEffect";
        AnimationName = "SonicPunchImpactAnimation";        
        Position      = %this.Position;
        Size          = "25 25";
    };
    
    // Fetch the Volume for the Effect.
    %volume = $Game::Player.getSoundVolume( %this.Position );
    
    // Play Sound Effect.
    //playSound( "SonicPunchImpactSound", %volume );
    
    %impactEffect.schedule(100,"SpawnMoreFlames",%this.Position.X - 5, %this.Position.Y);
    %impactEffect.schedule(100,"SpawnMoreFlames",%this.Position.X + 5, %this.Position.Y);
    %impactEffect.schedule(150,"SpawnMoreFlames",%this.Position.X - 10, %this.Position.Y);
    %impactEffect.schedule(150,"SpawnMoreFlames",%this.Position.X + 10, %this.Position.Y);
    %impactEffect.schedule(200,"SpawnMoreFlames",%this.Position.X - 15, %this.Position.Y);
    %impactEffect.schedule(200,"SpawnMoreFlames",%this.Position.X + 15, %this.Position.Y);
}

function MolotovImpactEffect::onAddToScene( %this )
{
   %this.DamageValue = 10;
   
   // Make sure this object doesn't collide but still interacts
   %this.setCollisionActive( 0, 1 );
   %this.setCollisionPhysics( 0, 0 );
   
   %this.setCollidesWith( "" );
   %this.schedule(1000,"Update");
   
   %this.Hitbox = new t2dSceneObject()
   {
       ObjectType = "EnemyHitbox";
       ActorType = "Invulnerable";
       Scenegraph = %this.Scenegraph;
       Size = %this.Size;
       Owner = %this;
       CollisionPolyList = %this.CollisionPolyList;
   };
    
   %this.Hitbox.setCollisionActive(1,1);
   %this.Hitbox.setCollisionPhysics(0,0);
   %this.Hitbox.setCollidesWith("PlayerObject");
   %this.Hitbox.mount( %this );
}

function MolotovImpactEffect::SpawnMoreFlames( %this, %x, %y )
{
// Create Impact Animation.
      %impactEffect = new t2dAnimatedSprite()
      {
         SceneGraph    = %this.getSceneGraph();
         Class         = "MolotovImpactEffect";
         AnimationName = "SonicPunchImpactAnimation";        
         Position      = %x SPC %y;
         Size          = "25 25";
      };
    
      // Fetch the Volume for the Effect.
      //%volume = $Game::Player.getSoundVolume( %this.Position );
    
      // Play Sound Effect.
      //playSound( "SonicPunchImpactSound", %volume );
}

function MolotovImpactEffect::onAnimationEnd( %this )
{
   %this.safeDelete();
}