Sorting SimSets (A Code Snippet)

I'm on my third situation where I want to sort a simset. Each time, though, the criterion for sorting is different. Maybe I want to sort by position.y or maybe by some "natural order" field I keep around or maybe by the "cost" of buying the items in the SimSet. I was uncomfortable writing and debugging a new sort for each situation.

The solution for me is a simple "bubble sort" that takes the sort criterion as an input function. If you have used C's qsort(), you get the interface already. Here is the code:

function easySort(%set, %comparator)
{
   for (%i = 0; %i < %set.getCount() - 1; %i++) {
      %minIndex = %i;
      for (%j = %i + 1; %j < %set.getCount(); %j++) {
         %which = call(%comparator, %set.getObject(%minIndex), %set.getObject(%j));
         if (%which > 0)
            %minIndex = %j;
      }
      if (%minIndex != %i)
         %set.reorderChild(%set.getObject(%minIndex).getId(), %set.getObject(%i).getId());
   }
}

That's it! Now for the harder part. Each call must provide a "comparator" function of the form "compare(%a, %b)". The comparator must return a negative number if a should be sorted first, positive if b should go first, and 0 if they are equal. With this function, easySort can sort any SimSet.

Here's an example to sort by the y position of your objects:

easySort(%mySimSet, yComparator);

function yComparator(%a, %b)
{
   return %a.position.y - %b.position.y;
}

Get it? If we return a's value minus b's value, then if a's is smaller, I'll get a negative number. If they are the same, I'll get 0, and if a's is bigger, I'll get a positive. If I wanted to sort in reverse order, I would change the last line to "return %b.position.y - %a.position.y;"

One more example, this time with some spit on it to show it can get complicated (though nowhere near as bad as making little sorts all over your code that have to do the same thing anyway). This time, I have a field, in my ButtonBehavior, named naturalOrder. No matter what order things are created I want to sort by this order. However, if the natural order field is -1, I'm basically saying, I don't care what order I'm end. Just put me at the end somewhere. With that, here's the comparator:

function buttonComparator(%a, %b)
{
   %aOrder = %a.getBehavior(ButtonBehavior).naturalOrder;
   %bOrder = %b.getBehavior(ButtonBehavior).naturalOrder;

   if (%aOrder == -1 && %bOrder != -1) return 1;
   if (%aOrder != -1 && %bOrder == -1) return -1;
   return %aOrder - %bOrder;
}

Caveats:
Well you could probably write a faster sort, but this one is full TorqueScript and does the best it can (or at least the best I can think of) with the SimSet interface. For instance, you can't swap two elements in the SimSet interface; you have to reorder(). To that end, this will be fast enough for small SimSets or for a little larger SimSets that you run once a level. To beat the performance, though, you'd probably need to find a way to just have your SimObjects pre-sorted somehow.