T3D Mounted Flashlight Resource

Updated: Lens/Lightflare and mountOffset added to Step 3.

Credit goes to deepscratch for helping me figure out how to add "cookies" into a spotlight and in the process fix some of the problems I was having with the flashlight code.


Created and Tested with T3D 1.1 Beta3


Fairly straightforward installation, Most of these were added at the bottom of the corresponding files unless noted otherwise.

1. In your 'scripts/client/default.bind.cs' file, Add:

$FlashlightVar = "1";
function toggleFlashlight(%val)
{
   if (%val)
   {
      if($FlashlightVar)
      {
         $FlashlightVar = "0";
         commandToServer('EnableFlashlight');
      }
      else
      {
         $FlashlightVar = "1";
         commandToServer('DisableFlashlight'); 
      }
   }
}
moveMap.bind( keyboard, f, toggleFlashlight );

What we have done here is setup the default.bind to toggle between sending an Enable or Disable command to the server side depending on what the $FlashlightVar is, by default the flashlight has just been disabled so the first toggle will always be to Enable.

2. In your 'scripts/server/commands.cs' file, Add:

//------------------------------------------------------------------------------
// Flashlight Controls
//------------------------------------------------------------------------------

function serverCmdEnableFlashlight(%client)
{
   %player = %client.player;
   %player.FlashlightEnable();
}

function serverCmdDisableFlashlight(%client)
{
   %player = %client.player;
   %player.FlashlightDisable();
}

These are the server commands that we just told are default.bind to call, this is how we get our clientID and send the FlashlightEnable/Disable command to the specific player that called it.


3. In your 'scripts/server/players.cs' file, Add:

//----------------------------------------------------------------------------
// Enable/Disable Player Flashlight
//----------------------------------------------------------------------------
function Player::FlashlightEnable(%this)
{
      // spotlight
      %light = new SpotLight() // In here you can add the example datablock values for more control
      {   
         range = "40";
         cookie = "art/gui/light.png"; // Basic Lighting will not render this.

         // Lens Flare will need a good mount and will need the mountOffset of the Flashlight 
         // to be modified for your specific application.
         flareType = "LightFlareExample1"; 
      };
      %this.mountobject(%light, 0, "0.05 0.68 -0.09"); // mountobject(%obj, mountNode, mountOffset)
      %this.light = %light;
}

function Player::FlashlightDisable(%this)
{
      // delete lights
      if(isObject(%this.light))
         %this.light.delete();
}

This is where we actually decide what happens to the specifc player, in this case we are going to create/destroy a SpotLight mounted to the Mount0 node on your player model.


4. Delete your 'scripts/client/config.cs' file, or Add:

moveMap.bind(keyboard, "f", toggleFlashlight);

This is personal preferance, I would suggest deleting the config.cs file and letting your updated default.bind.cs file rebuild your config.cs.

5. Add light.png to your 'art/gui/' folder.
This is your texture overlay or "cookie" you can set up your own custom texture or use the one provided, thats up to you.(just make sure you have changed Step3 to point toward your texture)


6. Go ahead and start your game and you should have a flashlight you can toggle using the "f" key, Have fun and I hope you guys found this helpful!

Note: This has been "network" tested with dual instances of T3D and should work, please let me know if there are any errors as it should work out of the box.


Here is an example SpotLight datablock, you can transfer some of its values over to your SpotLight spawning for more customization:

new SpotLight(slTest) { //This is not needed at all, purely for informational use
   range = "32";
   innerAngle = "40";
   outerAngle = "65";
   isEnabled = "1";
   color = "1 1 1 1";
   brightness = "1";
   castShadows = "0";
   priority = "1";
   animate = "1";
   animationPeriod = "1";
   animationPhase = "1";
   flareScale = "1";
   attenuationRatio = "0 1 1";
   shadowType = "Spot";
   texSize = "512";
   overDarkFactor = "2000 1000 500 100";
   shadowDistance = "400";
   shadowSoftness = "0.15";
   numSplits = "1";
   logWeight = "0.91";
   fadeStartDistance = "13";
   lastSplitTerrainOnly = "0";
   representedInLightmap = "0";
   shadowDarkenColor = "0 0 0 -1";
   includeLightmappedGeometryInShadow = "0";
   position = "0 0 0";
   rotation = "0 0 0 0";
   mountPID = "";
   mountNode = "2";
   mountPos = "0 0 0";
   mountRot = "0 0 0 0";
   canSave = "1";
   canSaveDynamicFields = "1";
};

The Light.png is free to use in indie or commercial projects, I only ask for credit.