TGB Crowd Test pt. 2

Brian Wilson — 2008-05-19T21:51:17+00:00

Ok, time for an update on the TGB Crowd Test Generator. Last time I unveiled my first run at my crowd generator. At the time I created several art assets to handle color variation along with 2 variants of the shirt and pants graphic to mix things up a bit.

I've updated the system to use t2dSceneObject::setBlendColor() on a simple white template for each object. So now there is just 1 graphic for each art asset. This results in 7 different assets instead of 29 and and an exponential increase in runner variants from the previous 2178 unique possibilities:

And here a new movie with the updated code and an added background manager (again, 1 art asset using some tricks with setBlendColor(); )

www.youtube.com/watch?v=bFa0ROaEAhs
UPDATE: Vimeo version (much better) - www.vimeo.com/1214676

And a couple of screenshots, this of the new game running:

and a close-up of the action:

And now for the code. First a run-through of the variables used:

$UNITLAYERMIN = 5; // the closest layer of the runner anchor
$UNITLAYERMAX = 25; // the furthest layer of the runner anchor

$CLOSELIMIT = 32.5; // the X coord for the closest runner range
$FARLIMIT = -12.5; // the Y coord for the furthest runner range

$UNITWIDTHBASE = 10; // set the width base for runners
$UNITWIDTHVARIANT = 20; // set the +/-  width variation percentage
$UNITHEIGHTBASE = 10; // set the height base for the runners
$UNITHEIGHTVARIANT = 20; // set the +/- width variation percentage

$UNITSPEEDBASE = 10; // set the velocity base for the runners
$UNITSPEEDVARIANT = 20; // set the +/- velocity variantion percentage

$UNITSCALE = 25; // the degree of scale between distance variations

$thescenegraph = sceneWindow2D.getSceneGraph(); // global for the scenegraph

$STREAKERBOTTOM = 5; // percentage probability of runner having no pants
$STREAKERSHOES = 25; // percentage probability of runner having no shoes
$STREAKERTOP = 15; // percentage probablity of runner having no shirt

// vars for random clothing style
// using a naming convention of:
// <clothingtype><variant#>
// i.e. "shirt1"

$CLOTHINGPANTVAR = 2; // there are 2 pant graphic variants
$CLOTHINGSHIRTVAR = 2; // there are 2 shirt graphic variants

And the generator:

function newRunner()
{
   %thislayer = getRandom($UNITLAYERMIN,$UNITLAYERMAX);
   %rangeY = $CLOSELIMIT-$FARLIMIT;

   // algo to determine runners location in the depth field
   // 5% - Closest Quarter
   // 13% - 2nd Closest Quarter
   // 15% - 3rd Closest Quarter
   // 66% - Furthest Quarter
   %rangeFinder = getRandom(1,100);
   if(%rangeFinder>95){
     %rangeYhigh = $CLOSELIMIT;
     %rangeYlow = (%rangeY/4)*3;
     %speedmod = 1.50;
   } else if(%rangeFinder>82) {
     %rangeYhigh = (%rangeY/4)*3;
     %rangeYlow = (%rangeY/4)*2;
     %speedmod = 1.25;
   } else if(%rangeFinder>67){
     %rangeYhigh = (%rangeY/4)*2;
     %rangeYlow = (%rangeY/4);
     %speedmod = 1;
   } else {
     %rangeYhigh = (%rangeY/4);
     %rangeYlow = $FARLIMIT;
     %speedmod = 0.75;
   }
   %coordY = getRandom(%rangeYlow, %rangeYhigh);   
   
   // set the runners height and width /w variant factored
   // and then scale it based on location in depth field
   %sizebaseX = getRandom($UNITWIDTHBASE-($UNITWIDTHVARIANT/$UNITWIDTHBASE),
                        $UNITWIDTHBASE+($UNITWIDTHVARIANT/$UNITWIDTHBASE));
   %sizebaseY = getRandom($UNITHEIGHTBASE-($UNITHEIGHTVARIANT/$UNITHEIGHTBASE),
                        $UNITHEIGHTBASE+($UNITHEIGHTVARIANT/$UNITHEIGHTBASE));
   %sizescale = (%coordY+50)/($UNITSCALE+100);
   %size = %sizebaseX*%sizescale@" "@%sizebaseY*%sizescale;
   
   // spawn the root layer of the runner
   %runner = new t2dAnimatedSprite() {
      scenegraph = $thescenegraph;
      imageMap = "runnerBaseImageMap"; // 
      canSaveDynamicFields = "0";
      Position = "-76 " @ %coordY; //spawn on left side offscreen
      class = "runnerClass";
      size=%size;
      WorldLimitCallback = "1";
      WorldLimitMax = "75 100";
      WorldLimitMin = "-85 -100";
      WorldLimitMode = "KILL";
   };
   %runner.playAnimation(runnerBaseAnimation);
   %runner.setLayer(%thislayer);
   // set the speed based on base modded by variant range and depth field loc
   %runner.setLinearVelocityX(getRandom(($UNITSPEEDBASE-
                        ($UNITSPEEDVARIANT/$UNITSPEEDBASE))*%speedmod, 
                        ($UNITSPEEDBASE+($UNITSPEEDVARIANT/$UNITSPEEDBASE))
                        *%speedmod));

   // spawn the skin layer and mount it behind the root   
   %runnerSkin = new t2dAnimatedSprite() {
      scenegraph = $thescenegraph;
      imageMap = "skinImageMap";
      canSaveDynamicFields = "0";
      class = "runnerClass";
      size=%size;
      WorldLimitCallback = "1";
      WorldLimitMax = "75 100";
      WorldLimitMin = "-85 -100";
      WorldLimitMode = "KILL";
   };
   // generate the skin shade darkness
   %shade=getRandom(441, 1000)/1000;
   // generate the skin pigment and modify it by the shade
   // my starting color for skin was R252G228B186. Based on a shift of
   // +/- 20 degrees hue and +/- 50 lightness (what looked good in my tool)
   // I shifted the skin to +20deg hue and +50 lightness to figure out what
   // 100%/100%/100% would be for my top color, which ended up being
   // R254G253B221. I then shifted from my base
   // color to -20%deg Hue and +50 lightness to figure out my low hue shift of
   // R254G231B221. Now, knowing that R and B do not shift in my hue range,
   // I only needed to shift G from 91.3% to 100%. I took my base skin color
   // again and shifted it to -20% hue, -50% lightness to get my darkest pigment
   // which was R126G103B093 or R49.6%G40.7%B42.1%. I averaged these percentages
   // to 44.1%. So once I  apply my green shift, then apply the shading of
   // 44.1% to 100%.
   %runnerSkin.setBlendColor(%shade@" "@
                        (getRandom(913, 1000)/1000)*%shade@" "@%shade@" 1");
   %runnerSkin.playAnimation("skinAnimation");
   %runnerSkin.setLayer(%thislayer+1); // place behind root
   %runnerSkin.mount(%runner, "0.000 0.000"); // mount to center of root


   // spawn the shoe layer and mount it (if runner isn't streaking)
   if(getRandom(1,100)>$STREAKERSHOES){
      %shoes = "shoes1";
      %runnerShoes = new t2dAnimatedSprite() {
         scenegraph = $thescenegraph;
         imageMap = %shoes@"ImageMap";
         canSaveDynamicFields = "0";
         class = "runnerClass";
         size=%size;
         WorldLimitCallback = "1";
         WorldLimitMax = "75 100";
         WorldLimitMin = "-85 -100";
         WorldLimitMode = "KILL";
      };
      %runnerShoes.setBlendColor((getRandom(25, 100)/100)@" "@
                           (getRandom(25, 100)/100)@" "@(getRandom(25, 100)
                           /100)@" 1");
      %runnerShoes.playAnimation(%shoes@"Animation");
      %runnerShoes.setLayer(%thislayer-1);
      %runnerShoes.mount(%runner, "0.000 0.000");
   }

   // spawn the pants layer and mount it (if runner isn't streaking)
   if(getRandom(1,100)>$STREAKERBOTTOM){
      // there are 2 pant variants to chose from
      %pants = "pants"@getRandom(1,$CLOTHINGPANTSVAR);
      %runnerPants = new t2dAnimatedSprite() {
         scenegraph = $thescenegraph;
         imageMap = %pants@"ImageMap";
         canSaveDynamicFields = "0";
         class = "runnerClass";
         size=%size;
      };
      %runnerPants.setBlendColor((getRandom(25, 100)/100)@" "@
                           (getRandom(25, 100)/100)@" "@(getRandom(25, 100)
                           /100)@" 1");
      %runnerPants.playAnimation(%pants@"Animation");
      %runnerPants.setLayer(%thislayer-2);
      %runnerPants.mount(%runner, "0.000 0.000");
   }


   if(getRandom(1,100)>$STREAKERTOP){
      // there are 2 shirt variants to chose from
      %shirt = "shirt"@getRandom(1,$CLOTHINGSHIRTVAR);
      %runnerShirt = new t2dAnimatedSprite() {
         scenegraph = $thescenegraph;
         imageMap = %shirt@"ImageMap";
         canSaveDynamicFields = "0";
         class = "runnerClass";
         size=%size;
         WorldLimitCallback = "1";
         WorldLimitMax = "75 100";
         WorldLimitMin = "-85 -100";
         WorldLimitMode = "KILL";
      };
      %runnerShirt.setBlendColor((getRandom(25, 100)/100)@" "@
                           (getRandom(25, 100)/100)@" "@(getRandom(25, 100)
                           /100)@" 1");
      %runnerShirt.playAnimation(%shirt@"Animation");
      %runnerShirt.setLayer(%thislayer-3);
      %runnerShirt.mount(%runner, "0.000 0.000");
   }
 }

My next steps are to do one more version of the generator demo, and also to strip the thing down completely to bare bones for a simple benchmarking tool for release (~2.5MB download).

TGB Crowd Test pt. 1

Brian Wilson — 2008-05-10T17:58:38+00:00

On the advice of Kevin James from this blog discussion, I've decided to start posting the various toys/tools/PoCs that I create when toying with the Torque engines.

I was an early adoptor of TGB(then T2D) and find myself coming back to it regulary with intent of pulling a game together, but I just have too much fun using it as a toy to make silly concepts come true.

So here it is in all of its Youtube FLV artifact-riddled glory:
www.youtube.com/watch?v=MD3_S1CWlgM

What started out as a quite nice 720p capture of a 1400x768 TGB window got utterly pixelated by its business no matter how many knobs I twisted on my various FLV converts. So I gave up and here's what you have. Enough of the video survived to show the concept at work.

Basically, what I've made is a crowd generator. Each runner is a 5-layer chain of mounted objects that are spawned randomly on the Y-axis off-screen in the -100< land then run toward the Happy Kill Box in the >100 Y-axis land. The following matrices are used in each generation:

- 3 different skin tones
- 2 different shirts with 5 colors each
- 2 different pants with 5 colors each
- 1 set of shoes with 5 colors each
- Height baseline with a +/- 20% modifier
- Width baseline with a +/- 20% modifier
- VelocityX with a +/- 20% modifier
- Y-axis picker
- %this.setLayer(getRandom(5,25)
- sexy streaker probability algorithm

The runners are put together with the stick-figure outline as the parent and the rest of the components are mounted to that with a layer offset, inheritting position, velocity, height offset, width offset.

On my system I can run aproximately 6000 objects (~1250 runners) onscreen and hover at around ~45-55 FPS both in fullscreen at 1600x1050 or windowed at 1400x768. Certainly performance would be better with less background stuff running and a built project without all the editing tools enabled.

Current Issues:
The only real issue I have so far is an obvious clash between 5-layer runners and TGB's 30-layer limit. I may look into a solution later

Moving Forward:
I want to work in the RGBtoHSV and rotateHue resource to give my runners unlimited clothing colors as well as a broad spectrum of skin tones. But fear not, the streaker code remains in tact at all costs!

I also still need to put in widgets for benchmarking, currently I have just setDebugOn(0) bound to a key, but I will put gui controls in for adjusting variables real-time as well as to provide performance and statistical feedback.

Once I've beat this horse to death, I'll post the code either in a blog or as a TDN article.

EDIT: Just to add a couple of Images:

Close-up cross-cut of the scene:

And an exploded view of the 2-5 runner objects, depending on how "free" he wants to be ;p

Blog for Brian Wilson at GarageGames.com

TGB Crowd Test pt. 2

TGB Crowd Test pt. 1