Cone of Fire with Recoil

Download Code File

EXPLANATION
-----------
This is my first resource so please expect that there might be a few errors that need to be addressed. I am a programmer but I am still on the C++ learning curve. My code could probably be done better.

Excuses out of the way, this resource adds two new functions to the TGE: a cone of fire and recoil effect. Both of these effects are implemented in several major-market FPS games, most notably the Medal of Honor and Battlefield series. This was inspired by this resource.

The first function is a "cone of fire" effect. Projectiles fired from the weapon do not always follow the crosshairs, rather fall within a theoretical cone extending from the muzzle of the weapon. As the weapon fires, the cone expands. Between rounds the crosshairs retract, shrinking the cone. This resource includes a crosshair GUI object that contains scripting hooks for setting the cone of fire per weapon datablock, as well as a hook for communicating client-side cone size to the server WITHOUT using a mask bit in the engine.

The second effect is an alteration of the pitch of the player based on the current cone of fire.

Both effects combined make for an extremely realistic weapons behavior. This resource has not been tested on vehicle mounted weapons, but there is no reason that I can see why it would not work.

You can see a sample in this movie. Note that our GUI is hardly finished. ;)

INSTRUCTIONS
------------
Unzip the file above into your engine/game/fps/ directory and add it to your project. Recompile.

Open Starter.fps/server/scripts/weapons.cs and add the following:

function serverCmdUpdateClientCoF(%client,%bloom)
{
	//	Save it on the client object for later use.
	%client.currentCoF = %bloom;
}

In the same file, change WeaponImage::onMount to look like the following:

function WeaponImage::onMount(%this,%obj,%slot)
{
   // Images assume a false ammo state on load.  We need to
   // set the state according to the current inventory.
   if (%obj.getInventory(%this.ammo))
      %obj.setImageAmmo(%slot,true);
      
  commandToClient(%obj.client,'CoFUpdate',%this.baseCoF,%this.coFBloom);   
	%obj.currentCoF = %this.baseCoF;
}

Open Starter.fps/client/scripts/game.cs and add the following:

function clientCmdCoFUpdate(%baseCoF, %coFBloom)
{
   CoFCrosshair.addBloom = %coFBloom;
   CoFCrosshair.baseBloom = %baseCoF;
   pitch(0 - (%coFBloom / 2)); // Season to taste
   CoFCrosshair.setBloom(0);
}

function updateServerCoF(%bloom)
// This function is called from the crosshair GUI object from within the engine.
{
	commandToServer('updateClientCoF',%bloom);
	echo ("Sending Bloom:" @ %bloom);
}

Open Starter.fps/client/ui/playGui.cs and replace the current Crosshair datablock with this one.

new GuiCoFCrossHairHud(CoFCrosshair) {
      profile = "GuiDefaultProfile";
      horizSizing = "center";
      vertSizing = "center";
      position = "384 256";
      extent = "256 256";
      minExtent = "8 2";
      visible = "1";
      damageFillColor = "0.000000 1.000000 0.000000 1.000000";
      damageFrameColor = "1.000000 0.600000 0.000000 1.000000";
      damageRect = "50 4";
      damageOffset = "0 32";
      baseBloom = "5";
      addBloom = "10";
      maxBloom = "64";
      crossHairColor = "0.800000 0.800000 0.800000 1.000000";
   };

Open the file for the weapon you wish to add this effect to. In the ShapeBaseImageData datablock definition, add the following:

baseCoF = 5;  // Season to taste
   coFBloom = 10;  // Season to taste
   projectileCount = 1;  // Provides for multiple projectile weapons like shotguns

In the same file, change the onFire method of your weapon to match the following:

function SMGImage::onFire(%this, %obj, %slot)
{
   %projectile = %this.projectile;

   // Decrement inventory ammo. The image's ammo state is update
   // automatically by the ammo inventory hooks.
   %obj.decInventory(%this.ammo,1);

	%spread = %obj.client.currentCoF / 2000;  // Season to taste

	// Create each projectile and send it on its way 
	for(%shell=0; %shell<%this.projectileCount; %shell++)
	{
		// Get the muzzle vector. This is the dead straight aiming point of the gun
		%vector = %obj.getMuzzleVector(%slot);
		
		// Get our players velocity. We must ensure that the players velocity is added 
		// onto the projectile
		%objectVelocity = %obj.getVelocity();
		
		// Determine scaled projectile vector. This is still in a straight line as 
		// per the default example
		%vector1 = VectorScale(%vector, %projectile.muzzleVelocity);
		%vector2 = VectorScale(%objectVelocity, %projectile.velInheritFactor);
		%velocity = VectorAdd(%vector1,%vector2);
		
		// Determine our random x, y and z points in our spread circle and create 
		// a spread matrix.
		%x = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%y = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%z = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%mat = MatrixCreateFromEuler(%x @ " " @ %y @ " " @ %z);
		
		// Alter our projectile vector with our spread matrix
		%velocity = MatrixMulVector(%mat, %velocity);

	   // Create the projectile object
	   %p = new (%this.projectileType)() {
	      dataBlock        = %projectile;
	      initialVelocity  = %velocity;
	      initialPosition  = %obj.getMuzzlePoint(%slot);
	      sourceObject     = %obj;
	      sourceSlot       = %slot;
	      client           = %obj.client;
	   };
	   MissionCleanup.add(%p);
	}
   commandToClient(%obj.client,'CoFUpdate',%this.baseCoF,%this.coFBloom);
   return %p;
}

Load your game and pull the trigger.

Once again, this is my first resource so please post if there are problems with your implementation. I am not by any means guarenteeing that this will work on all systems, and of course you should have read this resource fully and backed up your files prior to attempting to add this to your project. And .... I could have always forgotten something.

If anyone is looking to improve on this, I'd really like to see the addition of a bitmap array rather than drawing the cursor with dglDrawLine. You could then allow for custom crosshairs per weapon. This is just beyond my C++ ability at the moment.

Thanks to Harold "LabRat" Brown for the mask bit alternative.