Introduction

Several days ago somebody came on IRC and was wondering about video capturing of Torque 3D for cutscenes. I dug around the source code because I recall seeing something about it while I've been trying to get OpenGL working on Windows (that'll be another resource later on). I Lo and behold found these two console functions:

void startVideoCapture(
  GuiCanvas  canvas,
  string  filename,
  string  encoder = "THEORA",
  float  framerate = 30.0f,
  Point2I  resolution = Point2I(0, 0)
)
void stopVideoCapture()

But there were no examples nor any support functions in the stock scripts that come with Torque 3D that gave any hint as to how to use these functions, so after taking some time to figure them out I programmed my own helper function that works similar to the existing game journal/demo recording support functions:

//-----------------------------------------------------------------------------
// Theora Video Capture (Live Encoding)
//-----------------------------------------------------------------------------

// settings
$Recordings::VideoCap::Codec		= "THEORA";		// video codec to encode with
$Recordings::VideoCap::Framerate	= 30;			// video capture frame rate
$Recordings::VideoCap::MaxFileNum	= 1000;			// maximum file number to try

// please leave alone
$Recordings::VideoCap::isCapping	= false;
$Recordings::VideoCap::CapFile		= "";
$Recordings::VideoCap::CapFileExt	= ".ogv";

// arguments:
//		action -- boolean
//				true	Start video capture recording.
//				false	Stop video capture.
//				NOTE:	True while already capturing then it's same as doing:
//							videoCapControl(false); videoCapControl(true);
//
function videoCapControl(%action)
{
	/// stop recording video
	if($Recordings::VideoCap::isCapping)
	{
		$Recordings::VideoCap::isCapping = false;
		stopVideoCapture();
		ChatHud.AddLine( "\c4Video Capture [\c2" @ $Recordings::VideoCap::CapFile @ "\cr] finished.");
	}

	// abort on stop action since its completed by now
	if(!%action)
		return;

	/// start recording video

	// locate a non-existent filename to use
	for(%i = 0; %i < $Recordings::VideoCap::MaxFileNum; %i++)
	{
		%num = %i;
		if(%num < 10)
			%num = "0" @ %num;
		if(%num < 100)
			%num = "0" @ %num;

		%file = $currentMod @ "/recordings/videoCap" @ %num @ "";
		if(!isfile(%file @ $Recordings::VideoCap::CapFileExt))
			break;
	}

	// failed to locate an available filename
	if(%i > $Recordings::VideoCap::MaxFileNum)
	{
		ChatHud.AddLine( "\c3 *** Video Capture Failed: No unused filenames!");
		return;
	}

	// remember video capture file
	$Recordings::VideoCap::CapFile		= %file @ $Recordings::VideoCap::CapFileExt;
	$Recordings::VideoCap::isCapping	= true;

	// now begin recording
	startVideoCapture(Canvas, %file, $Recordings::VideoCap::Codec, $Recordings::VideoCap::Framerate);
	ChatHud.AddLine( "\c4Started Video Capture [\c2" @ $Recordings::VideoCap::CapFile @ "\cr].");

	// done
}

Usage Example

You can use this in two ways either manually in console or via your own script routines, or by incorporating it to the core scripts and using hotkeys to invoke the function. To use the function as it is briefly described within the comments above the function declaration, here are the usage examples:

// start recording to game/tools/recordings/videoCap0000.ogv
videoCapControl(true);

// stop recording game/tools/recordings/videoCap0000.ogv
videoCapControl(false);


// start recording to game/tools/recordings/videoCap0001.ogv
videoCapControl(true);

// stop recording game/tools/recordings/videoCap0001.ogv
// and immediately start recording to game/tools/recordings/videoCap0002.ogv
videoCapControl(true);

// now stop recording game/tools/recordings/videoCap0002.ogv
videoCapControl(false);

Implementation

Now here are the instructions on implementing the script function into the core scripts in the Examples/FPS Example/game/ provided game example. For those of you who prefer a patch file instead of manually doing this modification may download the patch file from any of these two sites:
T3DVideoCapScript20110206.patch -- Site A
T3DVideoCapScript20110206.patch -- Site B

NOTE: I already know about the strange timestamps in the patch file. All I can say is I used the latest WinMerge version on Windows XP to generate the patch file, so must be a bug.

Now on to business:
Edit file core/scripts/client/recordings.cs
and insert the videoCapControl() function provided above at the end of the recordings.cs file.

Next, edit file core/scripts/gui/optionsDlg.cs and insert this snippet after line 472 just after the last $RemapCounter++; line:

$RemapName[$RemapCount] = "Start Video Capture";
$RemapCmd[$RemapCount] = "videoCapStart";
$RemapCount++;
$RemapName[$RemapCount] = "Stop Video Capture";
$RemapCmd[$RemapCount] = "videoCapStop";
$RemapCount++;

And last edit file scripts/client/default.bind.cs and insert this snippet around line 529 right after moveMap.bind( keyboard, F4, stopRecordingDemo );:

function videoCapStart( %val )
{
   if ( %val )
      videoCapControl(true);
}

function videoCapStop( %val )
{
   if ( %val )
      videoCapControl(false);
}

moveMap.bind( keyboard, "alt F3", videoCapStart );
moveMap.bind( keyboard, "alt F4", videoCapStop );

Results

After finishing the implementation now you can use Alt+F3 to start video capture and Alt+F4 to stop video capture. Now you can of course open the options dialog and remap these keys to whatever you want them to be. I chose these default keys since F3 and F4 start and stop game journal/demo recording respectively. I hope you all liked this resource as it has been a long time since my last resource posting. Enjoy! :)