Simple Faking Melee with Raycasts

First up, the concept.

1. Use/fire an attack with a melee weapon
2. Play the animation of the attack
3. Raycast to see if anything is hit
4. Dole out damage if there was a hit

Secondly, what you'll need.

1. A melee weapon model
2. An animation for the melee attack
3. All necessary scripts to have the melee weapon supported by your player/Ai (inventory listings, maxInv[yourMeleeWeapon] = 1; in player.cs etc)
4. The melee weapon's script!

If they've run out of bullets then the player might be on a sticky wicket ... So in this example, we'll be using a cricketbat.

The cs file for art/datablocks is fairly similar to other weapons, except of course it doesn't require ammunition, the reload FSM is swapped to re-ready the weapon post fire.

datablock ItemData(cricketbat)
{
   category = "Weapon";
   className = "Weapon";
  shapeFile = "art/shapes/weapons/yorks/cricketbat.dts";
   mass = 12;
   elasticity = 0.2;
   friction = 0.6;
      maxVelocity = "15.0";

	pickUpName = "Cricket Bat";
	image = cricketbatImage;
	description = "Cricket Bat";
};

datablock ShapeBaseImageData(cricketbatImage)
{

  shapeFile = "art/shapes/weapons/yorks/cricketbat.dts";
   mountPoint = 0;
	eyeOffset = "0 0 0"; // 0.46=right/left 0.5=forward/backward, -0.5=up/down
//   correctMuzzleVector = true;//we don't have a muzzle for a melee weapon!
   className = "WeaponImage";
   item = cricketbat;

   stateName[0]                     = "Activate";
   stateTransitionOnTimeout[0]      = "Ready";
   stateTimeoutValue[0]             = 0.5;
   stateSequence[0]                 = "Activate";
   stateSound[0]                    = DrawWeaponSound;

   stateName[1]                     = "Ready";
   stateTransitionOnTriggerDown[1]  = "Fire";

   stateName[2]                     = "Fire";
   stateTransitionOnTimeout[2]      = "PostFire";
   stateTimeoutValue[2]             = 0.8;
//   stateRecoil[2]                   = MediumRecoil;
//you can use the stateRecoil if you want it to play the attack animation 
//and have it suitably linked in the player cs, 
//see below for alternative
   stateAllowImageChange[2]         = false;
   stateScript[2]                   = "onFire";
   stateSound[2]                    = meleeFireSound;

   stateName[3]                     = "PostFire";
   stateTransitionOnTimeout[3]      = "Ready";
   stateTimeoutValue[3]             = 0.1;//0.01 for 4 rps
   stateAllowImageChange[3]         = false;

};

The meat of the script is in the scripts cs file where we swap bullets for a raycast.

function cricketbatImage::onFire(%this, %obj, %slot)
{
	%obj.setActionThread("melee");

	%this.schedule(300, "Melee_attack", %obj);
}

You might want to actually make the animation play with the weapon's own recoil system in it's fire state, or like here, use an animation thread. If you find that your animation is coming out mangled because you're using a blend animation, then use the stateRecoil[#] for the animation and let the engine do the work on aligning the spine nodes correctly.

There should be a slight delay between firing the weapon/animation and actually doing the attack, so to simulate the initial swing of the weapon before it strikes. This should be dependant on how long your animation actually takes to strike out. In this example I'm using a fast strike off the forward foot towards Silly Mid-Off, so there's very little pull back for swing, and thus the delay is a mere third of a second before the test for contact and damage is scheduled.

Of course you'll want to check against something for recording hits, as well as have scenery stop the attack - unless you've a special love of wallhacks ...

$melee_check2hit = 
  $TypeMasks::VehicleObjectType |
  $TypeMasks::PlayerObjectType |
  $TypeMasks::TerrainObjectType |
  $TypeMasks::StaticTSObjectType |
  $TypeMasks::StaticShapeObjectType |
  $TypeMasks::ForestObjectType;

That about covers everything ... notice no dif in the above - embrace the future of static meshes. You could throw in the whole of shapebase if you want to drop players, vehicles, staticShape, etc.

You could use forwardVector but for this example it's a simple vector from the EyeNode, which goes out a mere 2 metres here. So if you're looking at the target and it's 2 units away, it'll get hit, otherwise it's a miss.

function CricketBatImage::Melee_Attack(%this, %obj)
{
    %eyeVec = %obj.getEyeVector();

    %startPos = %obj.getEyePoint();
    %endPos = VectorAdd(%startPos, VectorScale(%eyeVec, 2));
	  
    %target = ContainerRayCast(%startPos, %endPos, $melee_check2hit, %obj);
    %col = firstWord(%target);
   
	if(%col == 0) 
		return;
   	
	echo(%col);
	  //return the ID of what we've hit
	  
      // Apply damage to the object all shape base objects
	if (%col.getType() & $TypeMasks::ShapeBaseObjectType)
	{
		%col.damage(%obj, %pos, 15, "Cricket Bat Smack");
	  
		echo(%col.getname());

		%vpos = %col.getWorldBoxCenter();
		%pushDirection = VectorSub(%vpos,%obj.getWorldBoxCenter());
		%pushDirection = VectorNormalize(%pushDirection);

		%pushVec = VectorScale(%pushDirection,1000);
		%pushVec= getwords(%pushVec,0,1);
		%col.applyImpulse(%vpos, %pushVec);
	}
}

If you use a simple applyDamage() and the player gets killed the server will have issues dealing with the death - so it's important to deal out damage using the standard formula of %col.damage(%science_goes_here).
And finally, add an impulse to the attack to send the enemy flying over the boundary for a six!

And that's pretty much that ... remember to exec any new *.cs files that you've created.

You could of course ditch the whole idea of using weapons as the classic Torque weapon-scripted-objects, maybe use a simple punch attack where the keybind literally just fires the attack and animation, cutting out the whole weapons system and goes straight for the raycast as a function.

To get an Ai to use a melee type attack, is similar enough, just make it check whether the conditions are right for it to do so during it's think() cycle. Remember you'll have to check whether or not it's target is in range with a raycast to determine if it's worth a melee attack.

[edited] to clear up a few things, put a couple of warnings for animation problems you might stumble across and generally make it a little more complete for a novice