ArmorPiercing Projectiles + (Update: BUGFIX)

This has been created and tested with TGE 1.5.2 with the intent of having all the features Multiplay Compatible and ease of installation with Stock or Modded TGE.


Download AP Projectile + Source Files Here:
[url]http://torque.abigholeintheweb.com/public_system/useruploads/AP Projectiles Plus.zip[/url]
(Thanks to eb for the Unofficial Torque Public File System!)


This Resource includes:
Armor Piercing Rounds (w/ Decals)
Projectile Spread (Optionally Speed Based w/ Pre-Installed Multi Postion Resource)
Explode On Water (Surface)
Player Explosion (ex. Blood)
Vehicle Explosion (ex. Metal)

Credits go out to:
Armor Piercing was taken out of Ron Nelson's "Enhanced Projectiles" resource (Enhanced Projectiles resource not Multiplay compatible)
Water Explosions have been taken from Josh Moore's "Projectiles Explode on Water Impact" resource,
Projectile Spread was taken from Daniel Neilsen's "Projectile Spread and Shotguns" resource.
Vehicle/Player Explosions were taken from Thomas Tong's "Player Damage Explosion" resource.
Bullet Decals were taken from Tim Heldna's "Bullet Hole Decals" resource.

After you have installed the Projectile.cc and .h into your /engine/game/ folder and added it into your C++ Project, Compile and continue to the Script changes below:

Inside your "datablock ProjectileData(YourBullet)"

// / / AP + Projectiles / /
   playerExplosion = BulletBloodExplosion; //need your own blood explosion here
   vehicleExplosion = BulletMetalExplosion; //need your own vehicle explosion here

   decals[0] = medGenericDecal1; //these are defined in a decals.cs file you create later
   decals[1] = medGenericDecal2;
   decals[2] = medGenericDecal3;
   decals[3] = medGenericDecal4;
   decals[4] = medGenericDecal3;
   decals[5] = medGenericDecal2;  
   
   pierceOffset        = "1 1 1";
   explodeOnWater = true;
   // / / AP + Projectiles / /

After "datablock ShapeBaseImageData(YourWeaponImage)"

//-----------------------------------------------------------------------------
// Functions
function YourWeaponImage::onFire(%this, %obj, %slot) //replace "YourWeapon" with yourweapon
{
	// Decrease the weapons ammo on fire
	%obj.decInventory(%this.ammo,1);

	// Get the type of projectile we are gonna fire
	%projectile = %this.projectile;

   // if you are using the MultiPos resource then adjust these Velocity values accordingly...
   // its assumed that with the MultiPos resource you have differant speeds for each Pos...
   if( VectorLen(%obj.getVelocity()) > 3 )
      %SpeedSpread = (14.0 / 1000);
   else if ( VectorLen(%obj.getVelocity()) > 0.9 )
      %SpeedSpread = (10.0 / 1000);
   else if ( VectorLen(%obj.getVelocity()) > 0.1 )
      %SpeedSpread = (7.0 / 1000);
   else // if not using the MultiPosition resource then delete the entire if statement above...
      %SpeedSpread = (2.0 / 1000); 

	// Get the weapons projectile spread and ensure it is never 0 
	// (we need some spread direction even if it is extremely tiny)
	%spread = %SpeedSpread;
	%spread = %spread $= "" ? 0.001 : %spread;
	%spread = %spread <= 0 ? 0.001 : %spread;

	// Determine if we are using a shotgun class weapon or not
	// If we are using a shotgun, set the number of projectiles we are going to fire to 12
	%shellcount = 1;
	if(%this.isShotGun)
		%shellcount = 12;

	// Create each projectile and send it on its way 
	for(%shell=0; %shell<%shellcount; %shell++)
	{
		// Get the muzzle vector. This is the dead straight aiming point of the gun
		%vector = %obj.getMuzzleVector(%slot);

		// Get our players velocity. We must ensure that the players velocity is added 
		// onto the projectile
		%objectVelocity = %obj.getVelocity();

		// Determine scaled projectile vector. This is still in a straight line as 
		// per the default example
		%vector1 = VectorScale(%vector, %projectile.muzzleVelocity);
		%vector2 = VectorScale(%objectVelocity, %projectile.velInheritFactor);
		%velocity = VectorAdd(%vector1,%vector2);

		// Determine our random x, y and z points in our spread circle and create 
		// a spread matrix.
		%x = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%y = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%z = (getRandom() - 0.5) * 2 * 3.1415926 * %spread;
		%mat = MatrixCreateFromEuler(%x @ " " @ %y @ " " @ %z);

		// Alter our projectile vector with our spread matrix
		%velocity = MatrixMulVector(%mat, %velocity);


		// Create our projectile
		%p = new (%this.projectileType)()
		{
			dataBlock = %projectile;
			initialVelocity = %velocity;
			initialPosition = %obj.getMuzzlePoint(%slot);
			sourceObject = %obj;
			sourceSlot = %slot;
			client = %obj.client;
			isArmorPiercing  = true; //this is the original bullet
		};
		MissionCleanup.add(%p);
	}

	return %p;
}




function YourBullet::onPierce(%this,%obj,%startPos,%startVel)//replace "YourBullet" with yourbullet
{
   //Put together a dummy projectile
   //%this = projectile's datablock
   //%obj = the projectile instance
   // Create the projectile object;
   %weaponImage = %obj.sourceObject.getMountedImage($WeaponSlot);
   %p = new (%weaponImage.projectileType)() {
      dataBlock        = %this;
      initialVelocity  = %startVel;
      initialPosition  = %startPos;
      sourceObject     = %obj.sourceObject;
      sourceSlot       = %obj.sourceSlot;
      client           = %obj.client;
      isArmorPiercing  = false; //this is the second bullet...
   };

   MissionCleanup.add(%p);
   return %p;
}

Create a Decals.cs file and add:

// Medium Bullet Decal
datablock DecalData(medGenericDecal1)
{
   sizeX       = 0.07;
   sizeY       = 0.07;
   textureName = "~/data/textures/particles/bullethole";
};
datablock DecalData(medGenericDecal2 : medGenericDecal1)
{
   sizeX       = 0.09;
   sizeY       = 0.09;
   //textureName = "~/data/textures/particles/bullethole"; //uncomment these to have multi decals...
};

datablock DecalData(medGenericDecal3 : medGenericDecal1)
{
   sizeX       = 0.08;
   sizeY       = 0.08;
   //textureName = "~/data/textures/particles/bullethole";
};
datablock DecalData(medGenericDecal4 : medGenericDecal1)
{
   sizeX       = 0.05;
   sizeY       = 0.05;
   //textureName = "~/data/textures/particles/bullethole";
};

inside your game.cs file add: (Make sure this is exec'd BEFORE your weapons scripts!!!)

exec("./decals.cs");

Note: To keep this working for long-distance or slow-moving projectiles apply this fix:
http://www.garagegames.com/community/forums/viewthread/17909
Note: To keep this working for long-distance or slow-moving projectiles apply the fix!

I hope this helps!
If anyone has any problems let me know and I'll try to help you as much as I can. :)