Edit script files and functions during run-time

Open up your "console/consoleFunctions.cc" file and locate the console function "exec". You'll need to add a callback for this function to notify us of a newly executed script file.

ConsoleFunction(exec, ... )
{
    ...
    
    // ScriptUpdate Resource {
    if (ret)
        Con::executef(2, "onExec", scriptFileName);
    // }
    
    delete [] script;
    execDepth--;
    return ret;
}

Next, open up your "console/fileSystemFunctions.cpp" file and paste this new function in there somewhere (I put mine after the "fileSize" function).

ConsoleFunction(fileTime, S32, 2, 2, "(fileName)\n"
                                    "@param fileName The name of the file to check.\n" 
                                    "@return Returns the time of the last modification")
{
    argc;

    // Grab the full file address
    Con::expandScriptFilename(scriptFilenameBuffer, sizeof(scriptFilenameBuffer), argv[1]);
     
    // Return the time
    FileTime pModifyTime;
    if (Platform::getFileTimes(scriptFilenameBuffer, NULL, &pModifyTime))
        return (S32)pModifyTime.v1;
    
    return 0;
}

Finally, you need to add this package to your project. I placed mine in the root "main.cs" file (the first file to be called when the project is executed).

package ScriptUpdate
{
    function onExec(%fileName)
    {
        for (%i = 0; %i < $ScriptUpdate::Count; %i++)
        {
            if (getField($ScriptUpdate::Info[%i], 0) $= %fileName)
            {
                $ScriptUpdate::Info[%i] = trim(%fileName TAB fileTime(%fileName));
                return;
            }
        }
        
        $ScriptUpdate::Info[$ScriptUpdate::Count] = trim(%fileName TAB fileTime(%fileName));
        $ScriptUpdate::Count += 1;
    }
    
    function updateScripts(%val)
    {
        if (%val)
        {
            echo ("Updating Scripts...");
            
            for (%i = 0; %i < $ScriptUpdate::Count; %i++)
            {
                %fileName = getField($ScriptUpdate::Info[%i], 0);
                %fileTime = getField($ScriptUpdate::Info[%i], 1);
                
                if (fileTime(%fileName) != %fileTime)
                    exec (%fileName);
            }
        }
    }
};

//
activatePackage( ScriptUpdate );

Bind the function to a key for ease of use.

moveMap.bind( "keyboard", "ctrl l", "updateScripts" );

That is it!

When you load your game, it will store all of the files that you execute and the last time they were modified. If you then call the function "updateScripts()" during the game, it will re-execute any files that have been modified.

This little idea was inspired by the Plastic Tweaker resource from Plastic Games. I strongly recommend that you check it out!