script array

Arrays in TG* have some limitations, notably that you can't get a list of how many elements are in them, and that you can't pass them around directly. (you have to embed them inside an object, or some other such trick).

This resource is a trivial wrapper which does the bookkeeping of keeping an array in a script object.
It solves the two problems mentioned above.

The array is one-dimensional.

Note,
if you're interested in this, you might want to first check out this script-based array resource, which is a bit more full-featured.

////////////////////////////////////////////////////
//
// scriptArray.cs
//
// a script-only implementation of one-dimensional arrays which keep track of their members
// this is a very primitive array: the keys must be contiguous integers, starting at 0.
// o. elenzil 20080218
//
// usage:
//
// creation:
// %array = new_ScriptArray("");
// new_ScriptArray(someName);
//
// adding elements:
// %array.append(something);
// %array.set(index, something);
//
// retrieving elements:
// %array.get(%index);
//
// retrieving number of elements in the array:
// %array.size();
//
// dumping everything in the array:
// %array.dumpValues();


function new_ScriptArray(%name)
{
   %obj = new ScriptObject("ScriptArray");
   %obj.numElements = 0;
   %obj.setName(%name);
   return %obj;
}

function ScriptArray::append(%this, %value)
{
   %this.array[%this.numElements] = %value;
   %this.numElements++;
}

function ScriptArray::get(%this, %index)
{
   if (%index < 0 || %index >= %this.numElements)
   {
      error("ScriptArray::get()" SPC "- Subscript out of range:" SPC %index);
      return "";
   }
   
   return %this.array[%index];
}

function ScriptArray::set(%this, %index, %value)
{
   // note this allows you to go beyond the end of the array by one.
   if (%index > %this.numElements)
   {
      error("ScriptArray::set()" SPC "- Subscript out of range:" SPC %index SPC "value:" SPC %value);
      return;
   }

   if (%index == %this.numElements)   
      %this.append(%value);
   else
      %this.array[%index] = %value;
}

function ScriptArray::size(%this)
{
   return %this.numElements;
}

function ScriptArray::dumpValues(%this)
{
   for (%n = 0; %n < %this.numElements; %n++)
   {
      echo(%n SPC %this.get(%n));
   }
}