Scripted Experience and Attribute (stats) system

Greetings community,

I would first like to say that this community is awesome, and I have learned more here in the last two months than I did working with the Unreal Engine for about a year. I think that it is wonderful that there are so many talented people here that are willing to share what they know and have learned with the rest of the community.

When Nick and I were working on programming with TGE for the RPG we are working on we had noticed that there were TONS of wonderful resources available in the community, but we haven't found any functional systems for experience points or attributes. Although there are definitely some that touch up on these subjects.

The functionality in this resource was created by Nick Helton and Will Brown.

Without further ado...

So we want to have an experience system in our game. Wait a minute, what about attributes for the player? We need to have those too to make it believable right?

Do not worry, this will walk you through the entire process.

First we will do the initializing of the variables for the player in the game.cs class.

in "~\server\game.cs"

...
function GameConnection::createPlayer(%this, %spawnPoint)
{
   if (%this.player > 0)  {
      // The client should not have a player currently
      // assigned.  Assigning a new one could result in 
      // a player ghost.
      error( "Attempting to create an angus ghost!" );
   }

   // Create the player object
   %player = new Player() {
      dataBlock = PlayerBody;
      client = %this;
   
      [b]// HERE IS WHERE WE WILL BE GIVING OUR PLAYER SOME EXTRA STATS
      experience = 0;
      level = 0;

      //base attributes
      STR = 10;
      STA = 10;	
      AGI = 10;
      INT = 10;
      SPR = 10;

      //extended attributes
      HP = 0; 		// player's amount of life
      maxHP = 0; 	// player HP when fully healed
      MP = 0; 		// player's amount of mana
      maxMP = 0; 	// player's MP when fully replenished[/b]
   };
   MissionCleanup.add(%player);

   // Player setup...
   %player.setTransform(%spawnPoint);
   %player.setShapeName(%this.name);
   
   // Starting equipment
   %player.setInventory(Crossbow,1);
   %player.setInventory(CrossbowAmmo,10);
   %player.mountImage(CrossbowImage,0);

   // Update the camera to start with the player
   %this.camera.setTransform(%player.getEyeTransform());

   // Give the client control of the player
   %this.player = %player;
   %this.setControlObject(%player);
}

This code will set our player up to have 5 attributes or stats.

Strength is STR
Stamina is STA
Agility is AGI
Intellect is INT
Spirit is SPR

You can alter these to whatever will work best with the game you are creating. You will also notice some variables for tracking current and maximum HP and MP. We are using these for calculations that we will make later for increasing the maximum health and magic on the fly.

Now we need the bulkier bits of this resource. Time to delve into the player class.

in "~\server\player.cs"

...
//----------------------------------------------------------------------------

function Player::playDeathAnimation(%this)
{
   if (%this.deathIdx++ > 11)
      %this.deathIdx = 1;
   %this.setActionThread("Death" @ %this.deathIdx);
}

function Player::playCelAnimation(%this,%anim)
{
   if (%this.getState() !$= "Dead")
      %this.setActionThread("cel"@%anim);
}


//----------------------------------------------------------------------------

[b]//***************************************************************************

// added function to award experience to the player
function Player::awardExp(%this, %cl, %amount)
{
   %this.experience += %amount;

   //we got some points lets see if we gained a level
   %nextLevel = %this.level + 1;

   //This formula can be changed to your liking
   if(%this.experience >= %nextLevel * %nextLevel * 100)
   {
      commandToServer('awardLevel', %cl);
      commandToServer('updateAttributes', %cl);
   }
   else
   {
      // no level but xp points are good and we'll let you know it
      DisplayScreenMessage(%cl, "You got" SPC %amount SPC "xp.");
      echo("You got" SPC %amount SPC "XP!");
   }
  
}

function Player::awardLevel(%this, %cl)
{

   %this.level++;

   //these attributes always go up 2
   %this.STR += 2;
   %this.STA += 2;
   %this.AGI += 2;
   %this.INT += 2;
   %this.SPR += 2;

   DisplayScreenMessage(%cl, "You gained a level!" NL "You are now level: "@%this.level);
   echo("You gained a level!");
   echo("You are now level: "@%this.level);
}

function Player::updateAttributes(%this, %cl)
{
   // here we are updating all the stats the player
   // for example making sure that player maxHP = STA * 10
   // this will most likely be called at spawn and when gaining a level
   %this.maxHP = %this.STA * 10;
   %this.maxMP = %this.INT * 10;

   //you gained a level, have full health and mana!
   %this.HP = %this.maxHP;
   %this.MP = %this.maxMP;
}

// we should eventually put these somewhere else but this works for now
function serverCmdawardExp(%client, %amount)
{
   %client.player.awardExp(%client, %amount);
}

function serverCmdupdateAttributes(%client)
{
   %client.player.updateAttributes(%client);
}

function serverCmdawardLevel(%client)
{
   %client.player.awardLevel(%client);
}

//****************************************************************************************************
[/b]
function Player::playDeathCry( %this )
{
   %this.playAudio(0,DeathCrySound);
}
...

That will cover everything as far as setting up the commands and functions to level up and make the stats alter the player in some way, shape or form. Next we will do what we need to for the enemies. Please note that this was created with the AIGUARD resource in mind. We are using this resource as our base class for our enemies, and have decided to incorporate the bit about when the enemy dies into this class.

To do things as follows please go to www.garagegames.com/index.php?sec=mg&mod=resource&page=view&qid=6773 and install it. You won't regret it.

You back already? wow that was quick, Ok, now to continue. Let's go into the aiguard.cs class and alter one simple function to award the experience.

In "~\server\scripts\aiguard.cs"

[b]// At the top with the other global variables..
$AI_GUARD_XP_PER_KILL = 50;[/b]
...
function GuardPlayer::OnDamage(%this, %obj, %delta)
{
   		
	if(%delta < 0) //we are repairing, DON'T get stuck in a "defending" loop
		return;
		
      if (obj.action !$="GetHealth")
   	{
   			%obj.action = "Defending";
   	}
   	
   	[b]if(%obj.getstate() $="Dead") 
   	{
         %obj.action="Dead";
            //************************************************************************************************************
         //you killed that guy, have some experience points
         %client = ClientGroup.getObject(0);
         echo("We killed the mob, /joy");
         commandToServer('awardExp', $AI_GUARD_XP_PER_KILL);
   	}[/b]
   		
   	if(%obj.getState() $= "Dead" && %obj.respawn == true)
      {
         %obj.delaybeforerespawn(%obj.botname, %obj.marker);
         %this.player=0;
      }
}
...

*Edit* I added a variable initialization for the global used for determining the experience gained per kill. The changes are indicated in bold

That one was simple wasn't it?

That should be all you need for the back end of this stuff running, but now how do we know that it is working? We can visually see it happening much better if we have some sort of GUI to go by. Ok, let's create it.

This is the bonus portion with the statsGui.gui file. This one won't require too many changes. First let's go to the new file that you will be working with, of which, I will provide an example. Please also note that this example was highly inspired by the Inventory Gui resource.

Copy the following into a new .gui file and save it as statsGui.gui

"~\client\ui\statsGui.gui"

//--- OBJECT WRITE BEGIN ---
new GuiControl(StatsGUI) {
   profile = "GuiDefaultProfile";
   horizSizing = "right";
   vertSizing = "bottom";
   position = "0 0";
   extent = "640 480";
   minExtent = "8 2";
   visible = "1";

   new GuiWindowCtrl(StatsWindow) {
      profile = "GuiWindowProfile";
      horizSizing = "right";
      vertSizing = "bottom";
      position = "2 -2";
      extent = "621 476";
      minExtent = "8 2";
      visible = "1";
      text = "Stats";
      maxLength = "255";
      resizeWidth = "1";
      resizeHeight = "1";
      canMove = "1";
      canClose = "1";
      canMinimize = "1";
      canMaximize = "1";
      minSize = "50 50";
      CloseCommand = "Canvas.PopDialog(StatsGUI);";
     
    [b]new GuiObjectView(StatsItemView) {
	profile = "GuiDefaultProfile";
	horizSizing = "relative";
	vertSizing = "relative";
	position = "0 0";
	extent = "400 400";
	minExtent = "8 2";
	visible = "1";
	helpTag = "0";
	cameraZRot = "0";
	forceFOV = "0";
      };[/b]
      new GuiScrollCtrl() {
         profile = "GuiScrollProfile";
         horizSizing = "right";
         vertSizing = "bottom";
         position = "410 30";
         extent = "200 400";
         minExtent = "8 2";
         visible = "1";
         willFirstRespond = "1";
         hScrollBar = "alwaysOn";
         vScrollBar = "alwaysOn";
         constantThumbHeight = "0";
         childMargin = "0 0";

         new GuiTextListCtrl(StatsListView) {
            profile = "GuiTextArrayProfile";
            horizSizing = "right";
            vertSizing = "bottom";
            position = "2 2";
            extent = "178 2";
            minExtent = "8 2";
            visible = "1";
            enumerate = "0";
            resizeCell = "1";
            columns = "0";
            fitParentWidth = "1";
            clipColumnText = "0";
         };
      };
   };
};
//--- OBJECT WRITE END ---

function toggleStatsGUI(%val)
{
	if(%val)
      StatsGUI.toggle();
}

function StatsGUI::OnWake(%this)
{
	UpdateStatsListView();
}

//This function updates the StatsListView
function UpdateStatsListView()
{
	StatsListView.clear();	

	echo("Updating the players Stats...");
	
	%client = ClientGroup.getObject(0);
	
	//Health and Mana
	StatsListView.addRow(0,"Health:" SPC %client.player.maxHP);
	StatsListView.addRow(1,"Mana :" SPC %client.player.maxMP);

	//Experience and level
	StatsListView.addRow(2,"Experience:" SPC %client.player.experience);
	StatsListView.addRow(3,"Level :" SPC %client.player.level);
	
	//Attributes
	StatsListView.addRow(4,"STR :" SPC %client.player.STR);
	StatsListView.addRow(5,"STA :" SPC %client.player.STA);
	StatsListView.addRow(6,"AGI :" SPC %client.player.AGI);
	StatsListView.addRow(7,"INT :" SPC %client.player.INT);
	StatsListView.addRow(8,"SPR :" SPC %client.player.SPR);
	
	StatsListView.setSelectedRow(0);
	StatsListView.scrollVisible(0);
}

function StatsGUI::toggle(%this)
{
    if (%this.isAwake())
      Canvas.popDialog(%this);
    else
      Canvas.pushDialog(%this);
}

[b]function StatsListView::OnSelect( %this, %id, %text )
{
	%client = ClientGroup.getObject(0);
   
	StatsItemView.setEmpty();
        //Change the location of this dts to whatever you are using
	StatsItemView.setObject("player","starter.fps/data/shapes/player/player.dts","", 0);
}[/b]

[Edit]
If you have the guiObjectView.cc and guiObjectView.h files as part of your codebase please disregard this portion.

Please note that the items in bold above do not need to be implemented. If you want to pull this off with only scripting this will help you ascertain such a thing. If you don't have guiObjectView, or are trying to do this via scripting only, simply leave out the items that are marked in bold

If you would like to have the avatar, please go here and implement the guiObjectView files:
www.garagegames.com/index.php?sec=mg&mod=resource&page=view&qid=4063

After including them in your codebase, and re-compiling, linking and building the game engine, you should be good to go.

[/Edit]

Now that we have the GUI created, we need to set it up so that we can view the stats of this player at our choosing. To do this, we need to make some new commands to view it.

Add the following to your "~\client\scripts\default.bind.cs"

...
//Allows us to view our stats
moveMap.bind(keyboard,  c,          toggleStatsGUI);
...

Please also be sure to exec() this newly created GUI class wherever your other classes are being executed.

in "~\client\init.cs"

...
   //Character Stat/Exp sheet
   exec("./ui/statsGui.gui");
...

That should do it, you should now have attributes or stats, experience points, and a level. You should also be able to hit the 'c' key to view your stats at any time.

This can definitely be expanded on, and we plan on eventually taking things to the C++ engine route as we progress forward. We both had agreed that this is a wonderful starting point and wanted to share it with the rest of the community.

[edit]
Oh yes, don't forget to also map it in your optionsDlg.cs class.

In "~\client\scripts\optionsDlg.cs"

...
$RemapName[$RemapCount] = "Toggle Stats Dialog";
$RemapCmd[$RemapCount] = "toggleStatsGUI";
$RemapCount++;
...

Add this with the rest of the Interface Keys here and you should be good to go.