Enhanced Scoreboard (Score, Kills, Deaths)

Download Code File

This is my 'enhanced scoreboard' resource that displays score, kills, and deaths for each player. I thought
I'd share it as I've seen alot of people asking about this kind of thing. All the necessary code and
instructions are contained in the zip file. There are two script files (drop-in replacements for playerlist.cs
and playerlist.gui)

and a readme containing instructions on how to modify a stock starter.fps to make use of it.


I have tested this on a stock TGE 1.4 install and it works (initial values are blank until a kill or death occurs).

This code is a highly simplified version of what I'm using in my game, so errors are bound to exist. This is
primarily to demonstrate a method of extending the existing playerlist GUI. It is NOT a complete scoring
implementation, as that is up to the game developer. Anyway, this is my first resource so let me know
what you think.

This is the contents of the readme file:

Enhanced Scoreboard for TGE/TSE
by Midhir - Crossbones Studios
-------------------------------


To install, back up your old client/scripts/playerlist.cs and client/ui/playerlist.gui files. Replace them with
the files included in this archive.








Insert the following into your existing server/scripts/game.cs :
================================================================

/////-------------------------------------------------------------------------
// SCORE FUNCTIONS
/////-------------------------------------------------------------------------

function GameConnection::incKills(%client, %kill)
{
   %client.kills += %kill;
   
   messageAll('MsgClientScoreChanged', "", %client.score, %client.kills, %client.deaths, %client);
}

function GameConnection::incDeaths(%client, %death)
{
   %client.deaths += %death;
   
   messageAll('MsgClientScoreChanged', "", %client.score, %client.kills, %client.deaths, %client);
}

function GameConnection::incScore(%client, %score)
{
   %client.score += %score;

   messageAll('MsgClientScoreChanged', "", %client.score, %client.kills, %client.deaths, %client);
}

function GameConnection::getScore(%client)  { return %client.score; }
function GameConnection::getKills(%client)  { return %client.kills; }
function GameConnection::getDeaths(%client) { return %client.deaths;}

/////-------------------------------------------------------------------------
// END SCORE FUNCTIONS
/////-------------------------------------------------------------------------

If you are using an unmodified starter.fps from TGE, you can replace your GameConnection::onDeath() function with this:
================================================================================================

function GameConnection::onDeath(%this, %sourceObject, %sourceClient, %damageType, %damLoc)
{
   // Clear out the name on the corpse
   %this.player.setShapeName("");

   // Switch the client over to the death cam and unhook the player object.
   if (isObject(%this.camera) && isObject(%this.player)) {
      %this.camera.setMode("Corpse",%this.player);
      %this.setControlObject(%this.camera);
   }
   %this.player = 0;

   // Doll out points and display an appropriate message
   if (%damageType $= "Suicide" || %sourceClient == %this) {
      %this.incScore(-1);
      %this.incDeaths(1);
      messageAll('MsgClientKilled','%1 takes his own life!',%this.name);
   }
   else {
      %sourceClient.incScore(1);
      %sourceClient.incKills(1);
      %this.incDeaths(1);
      messageAll('MsgClientKilled','%1 gets nailed by %2!', %this.name, %sourceClient.name);
      if (%sourceClient.score >= $Game::EndGameScore)
         cycleGame();
   }
   messageAll('MsgClientScoreChanged', "", %client.score, %client.kills, %client.deaths, %client);
}

And in common/server/clientConnection.cs replace the function GameConnection::onConnect() with the following:
======================================

function GameConnection::onConnect( %client, %name )
{
   // Send down the connection error info, the client is
   // responsible for displaying this message if a connection
   // error occures.
   messageClient(%client,'MsgConnectionError',"",$Pref::Server::ConnectionError);

   // Send mission information to the client
   sendLoadInfoToClient( %client );

   // Simulated client lag for testing...
   // %client.setSimulatedNetParams(0.1, 30);

   // Get the client's unique id:
   // %authInfo = %client.getAuthInfo();
   // %client.guid = getField( %authInfo, 3 );
   %client.guid = 0;
   addToServerGuidList( %client.guid );
   
   // Set admin status
   if (%client.getAddress() $= "local") {
      %client.isAdmin = true;
      %client.isSuperAdmin = true;
   }
   else {
      %client.isAdmin = false;
      %client.isSuperAdmin = false;
   }

   // Save client preferences on the connection object for later use.
   %client.gender = "Male";
   %client.armor = "Light";
   %client.race = "Human";
   %client.skin = addTaggedString( "base" );
   %client.setPlayerName(%name);
   %client.score = 0;

   // 
   $instantGroup = ServerGroup;
   $instantGroup = MissionCleanup;
   echo("CADD: " @ %client @ " " @ %client.getAddress());

   // Inform the client of all the other clients
   %count = ClientGroup.getCount();
   for (%cl = 0; %cl < %count; %cl++) {
      %other = ClientGroup.getObject(%cl);
      if ((%other != %client)) {
         // These should be "silent" versions of these messages...
         messageClient(%client, 'MsgClientJoin', "", 
               %other.name,
               %other,
               %other.sendGuid,
               %other.score,
               %other.kills,  //Added by Midhir
               %other.deaths, //Added by Midhir
               %other.isAIControlled(),
               %other.isAdmin, 
               %other.isSuperAdmin);
      }
   }

   // Inform the client we've joined up
   messageClient(%client,
      'MsgClientJoin', '\c2Welcome to the Torque demo app %1.', 
      %client.name, 
      %client,
      %client.sendGuid,
      %client.score,
      %client.kills,   // Added by Midhir
      %client.deaths,  // Added by Midhir
      %client.isAiControlled(), 
      %client.isAdmin, 
      %client.isSuperAdmin);

   // Inform all the other clients of the new guy
   messageAllExcept(%client, -1, 'MsgClientJoin', '\c1%1 joined the game.', 
      %client.name, 
      %client,
      %client.sendGuid,
      %client.score,
      %client.kills,   // Added by Midhir
      %client.deaths,  // Added by Midhir
      %client.isAiControlled(), 
      %client.isAdmin, 
      %client.isSuperAdmin);

   // If the mission is running, go ahead download it to the client
   if ($missionRunning)
      %client.loadMission();
   $Server::PlayerCount++;
}