RPGDialog - NPC interaction system

function SpawnTestNPC()
{
   %player = AIPlayer::spawn("a test NPC","359.973 304.759 217.766");
   %player.RPGDialogScript = "Test";
   %player.RPGDialogPortrait = "Test.png";
   %player.RPGDialogStartQuestion = 1;
   %player.RPGDialogBusy = false;
   %player.RPGDialogBusyText = 'Sorry but I\'m busy talking to %1 right now.';
   %player.RPGDialogTalkingTo = 0;

   return %player;
}

function SpawnNPC(%Name,%Script,%Portrait,%startQuestion,%location)
{
   %player = AIPlayer::spawn(%Name,%location);
   %player.RPGDialogScript = %Script;
   %player.RPGDialogPortrait = %Portrait;
   %player.RPGDialogStartQuestion = %startQuestion;
   %player.RPGDialogBusy = false;
   %player.RPGDialogBusyText = 'Sorry but I\'m busy talking to %1 right now.';
   %player.RPGDialogTalkingTo = 0;
   
   return %player;
}

//-----------------------------------------------------------------------------
// RPGDialog - Presents the player with a question and several answers to select from
// Created by Nelson A. K. Gonsalves
//-----------------------------------------------------------------------------

function getAction(%actionFile,%questionNumber)
{
   %file = new FileObject();
   if(isFile($Pref::Server::RPGDialog::ActionPath@%actionFile@".dla") && %file.openForRead($Pref::Server::RPGDialog::ActionPath@%actionFile@".dla"))
   {
      for(%i=1;%i<%questionNumber;%i++)
      {
         %file.readLine();
         if(%file.isEOF())
            return "<Invalid Question>";
      }
      %action=%file.readLine();
   }
   else if(isFile($RPGDialogEditorPref::ActionPath@%actionFile@".dla") && %file.openForRead($RPGDialogEditorPref::ActionPath@%actionFile@".dla"))
   {
      for(%i=1;%i<%questionNumber;%i++)
      {
         %file.readLine();
         if(%file.isEOF())
            return "<Invalid Question>";
      }
      %action=%file.readLine();
   }

   %file.close();
   %file.delete();
   return %action;
}

function RPGDialogMessageClient(%client,%sender,%npcFile,%questionNumber)
{
   %senderName=%sender.getshapename();
   %portrait=%sender.RPGDialogPortrait;
   %playerName=%client.player.getshapename();

   %sender.RPGDialogBusy=true;
   %sender.RPGDialogTalkingTo=%client;
   %sender.setAimObject(%client.player);
   
   commandToClient(%client,'RPGDialogMessage',%sender,%senderName,%portrait,%npcFile,%questionNumber,%playerName);
   
   CheckRPGDialogStatus(%client,%sender);
}

function serverCmdRPGDialogAnswer(%client,%sender,%questionNumber,%answerNumber)
{
   if(%client==%sender.RPGDialogTalkingTo)
   {
      %npcFile=%sender.RPGDialogScript;

      %Actions=GetAction(%npcFile,%questionNumber);

      if(%Actions!$="<InvalidQuestion>")
      {
         if(strPos(%answerNumber,"QL")>=0)
         {
            %ActionHeaderSize=strlen("<"@%answerNumber@">");
            %NextActionHeaderSize=strlen("<"@getSubStr(%answerNumber,2,strLen(%answerNumber))+1@">");
            %ActionStart=strPos(%Actions,"<"@%answerNumber@">")+%ActionHeaderSize;
            %ActionEnd=strPos(%Actions,"<"@getSubStr(%answerNumber,2,strLen(%answerNumber))+1@">");
         }
         else
         {
            %ActionHeaderSize=strlen("<"@%answerNumber@">");
            %NextActionHeaderSize=strlen("<"@%answerNumber+1@">");
            %ActionStart=strPos(%Actions,"<"@%answerNumber@">")+%ActionHeaderSize;
            %ActionEnd=strPos(%Actions,"<"@%answerNumber+1@">");
         }


         if(%ActionEnd>=0)
         {
            %ActionEnd=%ActionEnd-%ActionStart;
         }
         else
         {
            %ActionEnd=strlen(%Actions);
         }

         // BrokeAss Games Multi-Response Add-On

         %SubActions=getSubStr(%Actions,%ActionStart,%ActionEnd);

      for(%i=1;%i<%ActionEnd;%i++){
      //%bla=true;
      //while(%bla){ <- Loops are bad

         %ParamStart=strPos(%SubActions,"(")+1;
         %ParamEnd=strPos(%SubActions,")")-%ParamStart;
         %Param=getSubStr(%SubActions,%ParamStart,%ParamEnd);

         %Action=getSubStr(%SubActions,0,%ParamStart-1);
         //echo("SubActions: " @ %SubActions); //Parser Debugging
         //echo("Action: " @ %Action @ " Param: " @ %Param); //Parser Debugging

         if(%Param!$="")
         {
            eval(%Action@"("@%Param@","@%client@","@%sender@",\""@%npcFile@"\");");
            %SubActions=getSubStr(%SubActions,%ParamEnd+%ParamStart+1,%ActionEnd);
         }
         else
         {
            eval(%Action@"("@%client@","@%sender@",\""@%npcFile@"\");");
            %SubActions=getSubStr(%SubActions,%ParamEnd+%ParamStart+1,%ActionEnd);
         }

         if(%SubActions$="-")
         {
            //%bla=false; // <- I said loops are bad
            break;
         }

        } // End Multi-Response Add-On
      }
      else
      {
      echo("ERROR::Invalid Question/Answer!!\nnpcFile = "@%npcFile@"\nquestionNumber = "@%questionNumber);
      }
   }
}

function serverCmdRPGDialogRay(%client)
{
   %StartPos=%client.player.gettransform();
   %Eye = %client.player.getEyeVector();
   %EndPos = vectorScale(%Eye, -1);
   %EndPos = vectorsub(%StartPos,%EndPos);

   InitContainerRadiusSearch(%EndPos, 0.5, $TypeMasks::PlayerObjectType);

   %rayCast=ContainerSearchNext();
   while(%rayCast != 0 )
   {
      if(%rayCast.aiPlayer && %rayCast.RPGDialogScript!$="")
      {
         if(!%rayCast.RPGDialogBusy)
         {
            RPGDialogMessageClient(%client, %rayCast, %rayCast.RPGDialogScript,%rayCast.RPGDialogStartQuestion); //start dialog.
            return;
         }
         else
         {
            if(IsRPGDialogBusy(%rayCast))
            {
               if(%client!=%raycast.RPGDialogTalkingTo)
               {
                  messageClient(%client, '', %rayCast.RPGDialogBusyText, %raycast.RPGDialogTalkingTo.player.getShapeName());
                  return;
               }
               else
                  return;
            }
            else
            {
               RPGDialogMessageClient(%client, %rayCast, %rayCast.RPGDialogScript,%rayCast.RPGDialogStartQuestion); //start dialog.
               return;
            }
         }
      }
      %rayCast=ContainerSearchNext();
   }
}

function IsRPGDialogBusy(%AiPlayerID)
{
   InitContainerRadiusSearch(%AiPlayerID.getTransform(), 3, $TypeMasks::PlayerObjectType);
   %rayCastBusyCheck=ContainerSearchNext();
   while(%rayCastBusyCheck != 0 )
   {
      if(%rayCastBusyCheck==(%AiPlayerID.RPGDialogTalkingTo).player)
      {
         return(true);
      }
      %rayCastBusyCheck=ContainerSearchNext();
   }
   return(false);
}

function CheckRPGDialogStatus(%Client,%Sender) //Checks if the player has moved since he started the dialog, moving too far from the sender will cancel the dialog
{
   InitContainerRadiusSearch(%Sender.getTransform(), 2, $TypeMasks::PlayerObjectType);
   %rayCast=ContainerSearchNext();
   while(%rayCast != 0 )
   {
      if(%rayCast==%Client.player)
      {
         schedule(1000,0,"CheckRPGDialogStatus",%Client,%Sender);
         return;
      }
      %rayCast=ContainerSearchNext();
   }
   CommandToClient(%client,'CloseRPGDialog');
   %Sender.RPGDialogBusy=false;
   %Sender.RPGDialogTalkingTo=0;
   %Sender.clearAim();
}

function SpawnTestNPC()
{
   %player = new AIPlayer() {
      dataBlock = PlayerBody;
      aiPlayer = true;
      RPGDialogScript = "Test";
      RPGDialogPortrait = "Test.png";
      RPGDialogStartQuestion = 1;
      RPGDialogBusy = false;
      RPGDialogBusyText = 'Sorry but I\'m busy talking to %1 right now.';
      RPGDialogTalkingTo = 0;
   };
   MissionCleanup.add(%player);

   // Player setup
   %player.setMoveSpeed(8);
   %player.setTransform(pickSpawnPoint());
   %player.setEnergyLevel(60);
   %player.setShapeName(%player);
   return %player;
}

//------------------------------------------------------------------------------
// RPGDialog Script Functions - functions bellow are made to be used by the
// dialog scripts.
// The commented out lines that start with <ActionList> are used when populating the action
// list on the RPGDialog Editor.
//------------------------------------------------------------------------------

//<ActionList>GotoQuestion(QuestionNumber)
function GotoQuestion(%questionNumber,%client,%sender,%npcFile)
{
   RPGDialogMessageClient(%client, %sender, %npcFile, %questionNumber);
}

//<ActionList>CloseDialog()
function CloseDialog(%client,%sender,%npcFile)
{
   //sendind nothing to the client will close the dialog without anything else happening
   %sender.RPGDialogBusy=false;
   %sender.RPGDialogTalkingTo=0;
}

//<ActionList>MoveTo(Position)
function MoveTo(%position,%client,%sender,%npcFile)
{
   %sender.setAimLocation(%position);
   %sender.setMoveDestination(%position);
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>KillPlayer()
function KillPlayer(%client,%sender,%npcFile)
{
   %client.player.kill("Sudden");
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>KillSender()
function KillSender(%client,%sender,%npcFile)
{
   %sender.kill("Sudden");
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>DamagePlayer(Amount)
function DamagePlayer(%DamageAmount,%client,%sender,%npcFile)
{
   %client.player.damage(0, %sender.getposition(), %damageAmount, "Sudden");
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>DamageSender(Amount)
function DamageSender(%DamageAmount,%client,%sender,%npcFile)
{
   %sender.damage(0, %sender.getposition(), %damageAmount, "Sudden");
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>TeleportPlayer(Position)
function TeleportPlayer(%Pos,%client,%sender,%npcFile)
{
   %client.player.setTransform(%Pos);
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>TeleportSender(Position)
function TeleportSender(%Pos,%client,%sender,%npcFile)
{
   %sender.setTransform(%Pos);
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>RenamePlayer(NewName)
function RenamePlayer(%NewName,%client,%sender,%npcFile)
{
   messageAllExcept(%client, -1, 'MsgPlayerRenamed', '\c1%1 is now known as %2.',%client.player.getshapeName(),%NewName);
   messageClient(%client, 'MsgPlayerRenamed', '\c1You are now known as %1.',%NewName);
   %client.player.setshapeName(%NewName);
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>RenameSender(NewName)
function RenameSender(%NewName,%client,%sender,%npcFile)
{
   messageAll('MsgAIRenamed','\c1%1 is now known as %2.',%sender.getshapename(),%NewName);
   %sender.setshapeName(%NewName);
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>ChangeStartQuestion(QuestionNumber)
function ChangeStartQuestion(%NewQuestion,%client,%sender,%npcFile)
{
   %sender.RPGDialogStartQuestion=%NewQuestion;
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>ChangeStartQuestionAndOpen(QuestionNumber)
function ChangeStartQuestionAndOpen(%NewQuestion,%client,%sender,%npcFile)
{
   %sender.RPGDialogStartQuestion=%NewQuestion;
   RPGDialogMessageClient(%client, %sender, %sender.RPGDialogScript,%NewQuestion);
}

//<ActionList>ChangeStartQuestionAndGoto(StartQuestion,GotoQuestion)
function ChangeStartQuestionAndGoto(%NewStartQuestion,%GoTo,%client,%sender,%npcFile)
{
   %sender.RPGDialogStartQuestion=%NewQuestion;
   RPGDialogMessageClient(%client, %sender, %sender.RPGDialogScript,%GoTo);
}

//<ActionList>ChangeScript(ScriptName,QuestionNumber)
function ChangeScript(%NewScript,%StartQuestion,%client,%sender,%npcFile)
{
   if(%NewScript!$="" && isFile($RPGDialogEditorPref::ActionPath@%NewScript@".dla"))
   {
   %sender.RPGDialogScript=%NewScript;
   %sender.RPGDialogStartQuestion=%StartQuestion;
   CloseDialog(%client,%sender,%npcFile);
   }
}

//<ActionList>ChangeScriptAndOpen(ScriptName,QuestionNumber)
function ChangeScriptAndOpen(%NewScript,%StartQuestion,%client,%sender,%npcFile)
{

   if(%NewScript!$="" && isFile($RPGDialogEditorPref::ActionPath@%NewScript@".dla"))
   {
      %sender.RPGDialogScript=%NewScript;
      %sender.RPGDialogStartQuestion=%StartQuestion;
      RPGDialogMessageClient(%client, %sender, %NewScript,%StartQuestion);
   }
}

//<ActionList>ChangePortrait(NewPortrait)
function ChangePortrait(%NewPortrait,%client,%sender,%npcFile)
{
   %sender.RPGDialogPortrait=%NewPortrait;
   CloseDialog(%client,%sender,%npcFile);
}

//<ActionList>ChangePortraitAndGoto(NewPortrait,QuestionNumber)
function ChangePortraitAndGoto(%NewPortrait,%QuestionNumber,%client,%sender,%npcFile)
{
   %sender.RPGDialogPortrait=%NewPortrait;
   RPGDialogMessageClient(%client, %sender, %sender.RPGDialogScript,%QuestionNumber);
}

//<ActionList>SellItem(Item,Price,Currency,Amount)
function SellItem(%item,%price,%currency,%amount,%client,%sender,%npcFile)
{
   if(%client.player.getInventory(%currency) >= %price){
   %client.player.incInventory(%item, %amount);
   %client.player.decInventory(%currency, %price);
   %sender.player.incInventory(%currency, %price);
   messageClient(%client, 'SellItem', '\c1You have purchased %1 %2(s) for %3 %4 from %5.',%amount,%item,(%price*%amount),%currency,%sender.name);
   } else {
   messageClient(%client, 'SellItem', '\c1You do not have %3 %4 to buy %1 %2(s) from %5.',%amount,%item,(%price*%amount),%currency,%sender.name);
   }

   //RPGDialogMessageClient(%client, %sender, %sender.RPGDialogScript,%QuestionNumber);
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>BuyItem(Item,Price,Currency,Amount)
function BuyItem(%item,%price,%currency,%amount,%client,%sender,%npcFile)
{
   if(%client.player.getInventory(%item) >= %amount){
   %client.player.decInventory(%item, %amount);
   %client.player.incInventory(%currency, %price);
   %sender.player.decInventory(%currency, %price);
   messageClient(%client, 'BuyItem', '\c1You have sold %1 %2(s) for %3 %4 to %5.',%amount,%item,(%price*%amount),%currency,%sender.name);
   } else {
   messageClient(%client, 'BuyItem', '\c1You do not have %1 %2(s) to sell for %3 %4 to %5.',%amount,%item,(%price*%amount),%currency,%sender.name);
   }
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>GiveItem(Item,Amount)
function GiveItem(%item,%amount,%client,%sender,%npcFile)
{
   if(%sender.player.getInventory(%item) >= %amount){
   %client.player.incInventory(%item, %amount);
   %sender.decInventory(%item, %amount);
   messageClient(%client, 'GiveItem', '\c1%3 has given you %1 %2(s).',%amount,%item,%sender.name);
   } else {
   messageClient(%client, 'TakeItem', '\c1%3 does not have %1 %2(s) to give you.',%amount,%item,%sender.name);
   }
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>TakeItem(Item,Amount)
function TakeItem(%item,%amount,%client,%sender,%npcFile)
{
   if(%client.player.getInventory(%item) >= %amount){
   %sender.player.incInventory(%item, %amount);
   %client.decInventory(%item, %amount);
   messageClient(%client, 'TakeItem', '\c1You have given %1 %2(s) to %3.',%amount,%item,%sender.name);
   } else {
   messageClient(%client, 'TakeItem', '\c1You do not have %1 %2(s) to give to %3.',%amount,%item,%sender.name);
   }
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>RewardItem(Item,Amount)
function RewardItem(%item,%amount,%client,%sender,%npcFile)
{
   %client.player.incInventory(%item, %amount);
   messageClient(%client, 'RewardItem', '\c1You have been rewarded %1 %2(s) by %3.',%amount,%item,%sender.name);
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>SayChat(ChatMessage)
function SayChat(%chatmessage,%client,%sender,%npcFile)
{
   messageClient(%client, 'SayChat', '\c1%1 Says: %2',%sender.name,%chatmessage);
   CloseDialog(%client,%sender,%npcFile);
}
//<ActionList>JoinFaction(Faction)
function JoinFaction(%teamid,%client,%sender,%npcFile)
{
   %client.joinTeam(%teamid);
   CloseDialog(%client,%sender,%npcFile);
}

%player = new AIPlayer() {
      dataBlock = PlayerBody;
      aiPlayer = true;
      RPGDialogScript = "Test"; <- Add
      RPGDialogPortrait = "Test.png"; <- Add
      RPGDialogStartQuestion = 1; <- Add
      RPGDialogBusy = false; <- Add
      RPGDialogBusyText = 'Sorry but I\'m busy talking to %1 right now.'; <- Add
      RPGDialogTalkingTo = 0; <- Add
      name = "MultiBot";
   };

if(%rayCast.aiPlayer && %rayCast.RPGDialogScript!$="")

common/RPGDialogEditor/editorMain.cs (204): Unable to find object: 'Answer2' attempting to call function 'delete'
common/RPGDialogEditor/editorMain.cs (205): Unable to find object: 'Action2' attempting to call function 'delete'
common/RPGDialogEditor/editorMain.cs (206): Unable to find object: 'editAnswer2Button' attempting to call function 'delete'
common/RPGDialogEditor/editorMain.cs (207): Unable to find object: 'moveAnswer2UpButton' attempting to call function 'delete'
common/RPGDialogEditor/editorMain.cs (208): Unable to find object: 'moveAnswer2DownButton' attempting to call function 'delete'

Fatal: (../engine/core/stringBuffer.cc @ 178) StringBuffer::cut - len >= 1.
Cannot display alerts in full screen mode. Dumping message to console...
Fatal: (../engine/core/stringBuffer.cc @ 178), StringBuffer::cut - len >= 1.