News GUI control for receiving news content from a web server

Download Code File

Well here is an on-line version of the news control's file data and I'll explain after it:

//--- OBJECT WRITE BEGIN ---
new GuiControl(NewsDlg) {
   profile = "GuiDefaultProfile";
   horizSizing = "right";
   vertSizing = "bottom";
   position = "0 0";
   extent = "640 480";
   minExtent = "8 8";
   visible = "1";
   helpTag = "0";

   new GuiWindowCtrl() {
      profile = "GuiWindowProfile";
      horizSizing = "center";
      vertSizing = "center";
      position = "75 36";
      extent = "618 459";
      minExtent = "300 200";
      visible = "1";
      helpTag = "0";
      text = "Game News!";
      maxLength = "255";
      resizeWidth = "1";
      resizeHeight = "1";
      canMove = "1";
      canClose = "1";
      canMinimize = "1";
      canMaximize = "1";
      minSize = "50 50";
      closeCommand = "Canvas.popDialog(NewsDlg);";

      new GuiScrollCtrl() {
         profile = "GuiScrollProfile";
         horizSizing = "right";
         vertSizing = "height";
         position = "8 26";
         extent = "132 400";
         minExtent = "8 8";
         visible = "1";
         helpTag = "0";
         willFirstRespond = "1";
         hScrollBar = "alwaysOff";
         vScrollBar = "dynamic";
         constantThumbHeight = "0";
         childMargin = "0 0";

         new GuiTextListCtrl(NewsList) {
            profile = "GuiTextListProfile";
            horizSizing = "right";
            vertSizing = "bottom";
            position = "1 1";
            extent = "130 8";
            minExtent = "8 8";
            visible = "1";
            helpTag = "0";
            enumerate = "0";
            resizeCell = "1";
            columns = "0";
            fitParentWidth = "1";
            clipColumnText = "0";
         };
      };
      new GuiButtonCtrl() {
         profile = "GuiButtonProfile";
         horizSizing = "right";
         vertSizing = "top";
         position = "8 432";
         extent = "133 21";
         minExtent = "8 8";
         visible = "1";
         command = "GetNews(NewsList.getRowTextById(NewsList.getSelectedId()));";
         helpTag = "0";
         text = "Refresh News";
         groupNum = "-1";
         buttonType = "PushButton";
      };

      new GuiScrollCtrl() {
         profile = "GuiScrollProfile";
         horizSizing = "width";
         vertSizing = "height";
         position = "146 26";
         extent = "465 426";
         minExtent = "8 8";
         visible = "1";
         helpTag = "0";
         willFirstRespond = "1";
         hScrollBar = "alwaysOn";
         vScrollBar = "alwaysOn";
         constantThumbHeight = "0";
         childMargin = "0 0";

         new GuiMLTextCtrl(NewsText) {
            profile = "GuiMLTextProfile";
            horizSizing = "width";
            vertSizing = "bottom";
            position = "1 1";
            extent = "457 14";
            minExtent = "8 8";
            visible = "1";
            helpTag = "0";
            lineSpacing = "2";
            allowColorChars = "0";
            maxChars = "-1";
            autoSizeWidth = true;
            autoSizeHeight = true;
         };
      };
   };
};
//--- OBJECT WRITE END ---

function NewsDlg::onWake(%this)
{
   // Web server to connect to in order
   // to download the news. Note ':80'
   // part must be left there or else
   // this will not work.
   $NewsHTTPHost="mywebserver.com:80";

   // Directory on the web server where
   // the news files are kept:
   $NewsHTTPPath="/path_to_news_dir/";
}

//----------------------------------------

function GetItemList()
{
   NewsList.entryCount = 0;
   NewsList.clear();
   %newsc = new HTTPObject(ItemList){};
   %newsc.get($NewsHTTPHost, $NewsHTTPPath @ "news.txt", "");
}

function ItemList::onLine( %this, %line )
{
   if(%line $= "[done]")
   {
      if($NewsName $= "")
      {
         NewsList.setSelectedRow(0);
      } else {
         %index = NewsList.findTextIndex($NewsName);
         NewsList.setSelectedRow(%index);
         //$NewsName="";
      }
   } else {
      NewsList.addRow( NewsList.entryCount, %line );
      %line = strreplace( %line, " ", "_" );
      %line = strlwr( %line );
      NewsList.fileName[NewsList.entryCount] = %line @ ".hfl";
      NewsList.entryCount++;
   }
}

function ItemList::onConnectFailed()
{
   MessageBoxOK("ERROR","Couldn't connect to news server to receive news!"@
   " The news server might be down for right now\n\nPlease try again later"@
   " at least 20 minutes from now. That will give it enough time to come back up.\n\nSorry :(");
}

function ItemList::onConnected()
{
}

function ItemList::onDisconnect()
{
}


//----------------------------------------

function NewsList::onSelect(%this, %row)
{
   GetNewsFile(%this.fileName[%row]);
}

function getNews(%NewsName)
{
   if(%NewsName !$= "") { $NewsName=%NewsName; }
   NewsList.entryCount = 0;
   NewsList.clear();
   GetItemList();

   //NewsList.setSelectedRow(0);
   Canvas.pushDialog(NewsDlg);
}

function GuiMLTextCtrl::onURL(%this, %url)
{
   // Check to see if the user clicked on
   // a section selection command link and
   // not an actual URL.
   %x = strpos( %url, ".." );
   if(%x !$= -1 ) {
      // yep it's a section selection command link!
      // Now let's see what section we should select
      // to automatically jump to that section.
      %call = getSubStr( %url, 0, %x );
      if(%call $= "news") { getNews(getSubStr( %url, %x + 2, strlen(%url) - %x )); }
   } else {
      // nope, it's just a URL. Therefore
      // open the user's default web browser
      // to that URL link that's provided.
      gotoWebPage( %url );
   }
}   

//-------------------------------------------

function GetNewsFile(%filename)
{
   %newsi = new HTTPObject(TheNews){};
   %newsi.get($NewsHTTPHost, $NewsHTTPPath @ %filename, "");
}

function TheNews::onLine( %this, %line )
{
   if(%line $= "[done]")
   {
      NewsText.setText($newslines);
      $newslines="";
   } else {
      $newslines=$newslines @ "\n" @ %line;
   }
}

function TheNews::onConnectFailed()
{
}

function TheNews::onConnected()
{
}

function TheNews::onDisconnect()
{
}

Now that data should be saved into a file named NewsGui.gui. Now the content of the file news.txt which is needed for all of this to work smoothly:

News Test
About Test
[done]

Now the content of news_test.hfl:

<just:center><lmargin%:5><rmargin%:95><font:Arial Bold:25>News Test!
<just:left>
<font:Arial Bold:20>[00/01/2002 @ 1:33 AM (CST)] - <a:t2n.org>TRON</a><font:Arial:16>
<font:Lucida Console:12>
This is a news test of my news control which I
scripted out myself! I hope you are happy with
the results...  :p

Also <a:news..About Test>click here</a> to find info about this test.

[done]

Content of about_test.hfl:

<just:center><lmargin%:5><rmargin%:95><font:Arial Bold:25>Abouts Test!
<just:left>
<font:Arial Bold:20>[00/01/2002 @ 1:33 AM (CST)] - <a:t2n.org>TRON</a><font:Arial:16>
<font:Lucida Console:12>
This is a news test of my news control which I
scripted out myself! Which I use the HTTPObject
to 'pull' the news right off of a web server
which I think is the smartest move to take to
provide a news model for on-line games. It's
simple and web-based dynamically generated
news could easily be implemented just by
tweating around with the news script a bit
and of course build a news system that works
on the web server such as using PHP.

[done]

Now you have the following files NewsGui.gui, news.txt, news_test.hfl, and about_test.hfl. Upload the last three files onto a web server and put the first file which is NewsGui.gui into your game's /[mod]/client/ui/ directory and don't forget to implement it into the game by editing init.cs file that's located one directory up from where you placed the news control at. Add this line in init.cs file:

exec("./ui/NewsGui.gui");

That will have the game loadup and process the news control for usage.


Now edit the NewsGui.gui control file and scroll down to the point where you see:

function NewsDlg::onWake(%this)
{
   // Web server to connect to in order
   // to download the news. Note ':80'
   // part must be left there or else
   // this will not work.
   $NewsHTTPHost="mywebserver.com:80";

   // Directory on the web server where
   // the news files are kept:
   $NewsHTTPPath="/path_to_news_dir/";
}

You need to edit both of those variable's values to your web server's address and path to where the news files are kept. Then save the file. After you have done all of this create a button somewhere in your game and put this line in command property:

getnews();

Now click on that new button and tada! If you did everything correctly it should have worked!

Sorry for the lack of comments in the code and the lack of information in this resource since this is my first resource posting I am not really sure what all I should disclose and it's pretty late right now, so I'm very tired.
I've also uploaded the files needed for all of this just in case someone is too lazy to copy and paste into notepad(or your favorite text editor) to do all of this.

I hope you all like this resource since I know this one could have helped me out a lot when I needed to know how to use HTTPObject.


ScreenShot: