Code Problem/Suggestions

Because if the varying results I've had when using the "castCollision()" and "onCollision" functions together on different Operating Systems, I'm now trying to make a platform game script that's movement is completely defined in the "onCollision" function.

Problems:
Jumpy on wall collisions (but at least not going through them ;) )
-any more?

Suggestions and problems with the following script would be appreciated. You're free to use and manipulate this code as well.





This assumes the player sends + receives collision (and nothing else) and the ground receives collision (and nothing else)


------------------------------------------------------------

function player::onCollision(%this, %dstObj, %srcRef, %dstRef, %time, %normal, %contactCount, %contacts) {  
   //-----For simplicity, I'm using local variables-----  
   %xvel = (%this.moveRight - %this.moveLeft) * %this.movespeed;          //the resulting x velocity
   %yvel = mTan(getWord(%normal, 0)) * %this.getLinearVelocityX();        //the resulting y velocity
   %angle = getWord(%normal, 1);                                          //the collision angle y (in radians)
   %jumpheight = %this.jump * -%this.jumpSpeed;                           //the height the player will jump

   //-----ceiling collision-----
   if(%angle > 0) {
	  %this.setPositionY(%this.getPositionY() + 1);
      %yvel = 4 - %jumpheight;
   }

   //-----wall collision (or too steep of a slope)-----  
   if(%angle > -0.3) {
      %yvel = %this.getLinearVelocityY();		
   
      if(%this.getLinearVelocityX() - %dstObj.getLinearVelocityX() < 0)
         %this.setPositionX(%this.getPositionX() + 1);
      if(%this.getLinearVelocityX() - %dstObj.getLinearVelocityX() > 0)
         %this.setPositionX(%this.getPositionX() - 1);

      %xvel = %dstObj.getLinearVelocityX();
      %jumpheight = 0;  
   }
		
   //-----if the player is on a rotating block-----  
   if(%dstObj.getAngularVelocity() != 0 && %this.getLinearVelocityX() == 0) 
      %yvel = ((%this.getPositionY() - %dstObj.getPositionX()) / %dstObj.getWidth() / 2);  
      
   //-----if the player is on a moving block-----  
      if(%dstObj.getLinearVelocityX() != 0)  
         %xvel = %dstObj.getLinearVelocityX() + %xvel;
      if(%dstObj.getLinearVelocityY() != 0)
         %yvel = %dstObj.getLinearVelocityY() + %yvel;
      
   //-----finally, set the speeds-----
   %this.setLinearVelocityX(%xvel);
   %this.setLinearVelocityY(%yvel + %jumpheight - 0.05);
}

------------------------------------------------------------



Oh, and if you want to use this code in a game, copy/paste this script in the same file:


------------------------------------------------------------

//----------start----------
function player::onLevelLoaded(%this) {
   %this.start();
   %this.loadAnimation();
}





//----------enablers----------
function player::start(%this) {

%this.gravity = 49.05; //gravitational effect on a 5N object
%this.setConstantForceY(%this.gravity);


   //-----variables-----
   %this.moveSpeed = 15;
   %this.jumpSpeed = 50;
   
   //---don't change---
   %this.jump = false;
   %this.moveLeft = 0;
   %this.moveRight = 0;


   //-----keybinds-----
   if(!isObject(moveMap)) {return;}
   moveMap.bindCmd(keyboard, "up", "player.Jump();", "player.stopJump();");
   moveMap.bindCmd(keyboard, "left", "player.left();", "player.stopLeft();");
   moveMap.bindCmd(keyboard, "right", "player.right();", "player.stopRight();");
   
   
   //-----collision-----
   %this.setCollisionActiveSend(true);
   %this.setCollisionActiveReceive(true);
   %this.setCollisionPhysics(false, false);
   %this.enableUpdateCallback();
   %this.setCollisionCallback(true);
}





//----------key commands----------
function player::Jump(%this) {
   %this.jump = true;
}
function player::stopJump(%this) {
   %this.jump = false;
}

function player::left(%this) {
   %this.moveLeft = 1;
   %this.setFlipX(1);
}
function player::stopLeft(%this) {
   %this.moveLeft = 0;
}

function player::right(%this) {
   %this.moveRight = 1;
   %this.setFlipX(0);
}
function player::stopRight(%this) {
   %this.moveRight = 0;
}





//----------movement code----------
function player::onUpdate(%this) {

   if((%this.moveRight - %this.moveLeft) == 0)
      %this.setAnimationFrame(0);
	  
   //%this.updateAnimation();
   
}

------------------------------------------------------------




Feedback would be greatly appreciated.