Libcurl implementation

if (!isObject(curler)) new ScriptGroup(curler);

/// Add new task for "binary" download (physical file on HDD)
/// %expectedSize and all params after are optional
function curler::addDownloadTask(%this, %url, %file, %expectedSize, %md5, %cbOK, %cbFailed, %cbProgress)
{
   %id = getStringMD5(%url);
   %sc = curler.findObjectByInternalName(%id);
   if (!isObject(%sc))
   {
      %sc = new SimCurl() { internalName = %id; };
      %this.add(%sc);
      %sc.setURL(%url);
      %sc.url = %url;
      if(%expectedSize<1) // we treat "", "0" or "-1" as "unknown"
         %sc.fileSizeExp = -1;
      else
         %sc.fileSizeExp = %expectedSize;
      %sc.setFileName(%file);
      %sc.file = %file;
      %sc.hash = %md5;
      // Callbacks
      %sc.callBack = %cbOK;
      if(%cbOK!$="")
         %sc.setFinishCallback(%cbOK);
      %sc.callBackFail = %cbFailed;
      if(%cbFailed!$="")
         %sc.setFailedCallback(%cbFailed);
      %sc.callBackProgress = %cbProgress;
      if(%cbProgress!$="")
         %sc.setProgressCallback(%cbProgress);
      %sc.ts = getSimTime();
      %sc.runCount = 0;
      if (isFile(%file) && fileSize(%file)==0)
      {
         if($curl::debug) error("Removing zero-sized file!");
         deleteFile(%file);
      }
      if (isFile(%file))
      {
         if($curl::debug) error("File exists!!!");
         %fileSize = fileSize(%file);
         if(%sc.fileSizeExp > 0 && fileSize(%file)==%sc.fileSizeExp)
         {
            if($curl::debug) error("We know the expected file size and file sizes are the same!");
            if(%sc.hash!$="" && strlwr(%sc.hash)$=getFileMD5(%file))
            {
               if($curl::debug) error("File sizes is the same and hashes too! Nothing to do!");
               schedule(10, 0, %sc.callBack, %sc);
               return true;
            }
            else
            {
               if($curl::debug) error("File size is the same, but hash is different! Deleting file!");
               fileDelete(%file);
            }
         }
         if(%sc.fileSizeExp > 0 && fileSize(%file) > %sc.fileSizeExp)
         {
            if($curl::debug) error("Existing file is greater than we expecting! Deleting file!");
            fileDelete(%file);
         }
         if(%sc.fileSizeExp > 0 && fileSize(%file)>0 && fileSize(%file) < %sc.fileSizeExp)
         {
            if($curl::debug) error("Setting resuming from:" SPC fileSize(%file));
            %sc.resumingFrom = fileSize(%file);
            %sc.setResumeFrom(%sc.resumingFrom);
         }
      }
      %sc.start();
      return true;
   }
   else
   {
      error("The download is already in progress... not starting a new one!!!");
      return false;
   }
}

/// Add new "text" task for download (useful for XML or plain-text ie no physical file but using buffer instead
function curler::addTextTask(%this, %url, %cbOK, %cbFailed, %cbProgress)
{
   %id = getStringMD5(%url);
   %sc = curler.findObjectByInternalName(%id);
   if (!isObject(%sc))
   {
      %sc = new SimCurl() { internalName = %id; };
      %this.add(%sc);
      %sc.setURL(%url);
      %sc.url = %url;
      // Callbacks
      if(%cbOK!$="")
         %sc.setFinishCallback(%cbOK);
      if(%cbFailed!$="")
         %sc.setFailedCallback(%cbFailed);
      if(%cbProgress!$="")
         %sc.setProgressCallback(%cbProgress);
      %sc.ts = getSimTime();
      %sc.start();
      return %sc;
   }
   return false;
}

function cbOK(%sc)
{
   echo(%sc SPC "Finished OK");
   %sc.delete();
}
function cbError(%sc)
{
   echo(%sc SPC "Not Finished, status:" SPC %sc.getStatus() );// Will return curl error code, like canceled or any other error code
   %sc.delete();
}
function cbProgress(%sc)
{
   echo("Downloading, currently at" SPC ((%sc.getSizeNow()/%sc.getSizeTotal())*100) @ "%");
);
}
function startBinaryDownload()
{
   curler.addDownloadTask("http://www.garagegames.com/", "starter.fps/cache/gg_index.html, -1, "", "cbOK", "cbError", "cbProgress");
}
function cbFinishedText(%sc)
{
   while(!%sc.isEOF())
   {
      %line = %sc.readLine();
   }
   %sc.delete();
}
function startTextDownload()
{
   curler.addTextTask("http://www.garagegames.com/", "cbFinishedText", "cbError", "cbProgress");
}

SimCurl.setURL(%url);
// Set URL to download/upload from/to

SimCurl.getURL();
// Retrieve url, just in case :)

SimCurl.setLogin(%loginName);
// sets login name for use in authentification

SimCurl.setPassword(%password);
// sets password for use in authentification

SimCurl.setFileName([%fileName]);
// If specified, the contents will be downloaded into physical file,
// otherwise still be stored in a buffer

SimCurl.setUploadFlag(%flagBool);
// you can set "upload" flag with this

SimCurl.perform();
// Start processing now without using threads, useful for debugging

SimCurl.start();
// Actually, start the download after everything is setup

SimCurl.isRunning();
// Returns true/false if it still running/working downloading/uploading)

SimCurl.getStatus();
// Get status of download (after complete/failure), see curl.h for error codes

SimCurl.readLine();
// Read line from buffer, can be used to parse TEXT/XML without storing files on HDD

SimCurl.isEOF();
// Used with .readLine() method to catch the end of buffer

SimCurl.getSizeTotal();
// Returns INT for the size of file being downloaded/uploaded.
// Will return zero if not (yet) known.

SimCurl.getSizeNow();
// Returns the "already-downloaded" amount of bytes

SimCurl.cancelDownload();
// Cancel currently downloaded file, will trigger callback for failure,
// so grab .getStatus() to catch cancellations

SimCurl.setResumeFrom(%bytes);
// You can tell curl to resume download/upload by specified bytes.

SimCurl.setProgressCallback(%funcName);
// Set the function name to call during downloading progress

SimCurl.setFinishCallback(%funcName);
// Set the function name to call when finished downloading (success)

SimCurl.setFailedCallback(%funcName);
// Set the function name to call when download failed or cancelled

Quote:Later will work on proper resource / documentation and fully-funcitonal script wrapper for easy maintaining the download/uploads

Quote:libcurl - the multiprotocol file transfer library

libcurl is a free and easy-to-use client-side URL transfer library, supporting FTP, FTPS, HTTP, HTTPS, SCP, SFTP, TFTP, TELNET, DICT, LDAP, LDAPS and FILE. libcurl supports SSL certificates, HTTP POST, HTTP PUT, FTP uploading, HTTP form based upload, proxies, cookies, user+password authentication (Basic, Digest, NTLM, Negotiate, Kerberos4), file transfer resume, http proxy tunneling and more!

libcurl is highly portable, it builds and works identically on numerous platforms, including Solaris, NetBSD, FreeBSD, OpenBSD, Darwin, HPUX, IRIX, AIX, Tru64, Linux, UnixWare, HURD, Windows, Amiga, OS/2, BeOs, Mac OS X, Ultrix, QNX, OpenVMS, RISC OS, Novell NetWare, DOS and more...

libcurl is free, thread-safe, IPv6 compatible, feature rich, well supported, fast, thoroughly documented and is already used by many known, big and successful companies and numerous applications.

SimCurl::~SimCurl()
{
	if(storagedesc.mem.ptr && SIMCURL_STORAGE_BUFFER)
		dFree(storagedesc.mem.ptr);
	if (_G.head)
		_G.head = NULL;
}

void SimCurl::threadFunction(S32 n)
{
	(void)n;
	while(_G.head) {
		_G.head->perform();
		Mutex::lockMutex(_G.mutex);
		if (_G.head)
			_G.head = _G.head->next;
		Mutex::unlockMutex(_G.mutex);
	}
}