TorqueScript FileObject path issues

#1 I found out the problem. In the TDN entry on reading/writing files (http://tdn.garagegames.com/wiki/TorqueScript_FileObject) , it uses a left and right quote, like so: "starter.fps/test.txt" (edit: Apparently, this forum is incapable of showing them. But trust me, they are there, and I can see them as I edit this post)

This, used in the TDN entry, actually stopped my script from working entirely, and returned an error. I changed it to regular quotes, and it returns no error. It just simply does not work :). I run "readFile();" in the console, and nothing happens. I made a write function as well (using no path, just a filename), and that also does nothing. not even returning an error. It echoes some test text I threw in the script, so I know it's running the function. The functions just don't write or read anything at all. It apparently thinks the path is valid. I don't know what's wrong. Am I giving the path properly? (yes, the path does actually point to the file. I'm just asking about syntax) It would return an error if it were wrong, right?

#2 David,

The problem isn't which direction slashes you are using, either should work. The problem is that, as far as I know, only object-fields can use the abbreviations such as "~". Before you pass something like this into any functions (in other words, not a field) you must expand it using the function "expandFilename()" which will convert abbreviations such as "." and "~" into their correct context. In your example, you want the "~" to be replaced with the current MOD context name; "expandFilename()" will do this for you.

Also, there are a few things I'd suggest to make this stuff safer. First is that you can quickly test for the presence of a file (at least one that the resource-manager knows about) with "isFile()" which returns a flag indicating if the file is valid. This saves you creating a file-object in the first place. On the subject of the "FileObject"; be careful to delete the object afterwards otherwise you'll leak memory.

You may know all this and your example was just for brevity but I thought it was good to point this out in case anyone else reads it as well.

Anyway, being as it's xmas and I'm feeling happy; here's an example of what I mean:

// Read Level-File Lines.
function readLevelFile( %filename )
{
	// Expand Filename Abbreviations.
	%filename = expandFilename(%filename);
	
	// Valid File?
	if ( isFile( %filename ) )
	{
		// Yes, so create File Object.
		%fileObject = new FileObject();
		
		// Open File?
		if ( %fileObject.OpenForRead(%filename) )
		{
			// Yes, so read File.
			while( !%fileObject.isEOF() )
			{
				// Read Line.
				%line = %fileObject.readline();
				// Echo Line.
				echo( %line );
			}
		}
		else
		{
			// No, so error.
			echo("readLevelFile() - Error opening level-file:" SPC %filename);
		}
		
		// Delete File Object.
		%fileObject.delete();
	}
	else
	{
		// No, so error.
		echo("readLevelFile() - Error locating level-file:" SPC %filename);
	}
}

... calling it with ...

// Read Level File.
	readLevelFile("~/client/levels/easy.txt");

I personally feel that at least the "FileObject" should automatically expand the filename and taken to its furthest extreme, added to the resource-manager for any file-resources that are selected. I'm sure there's a good reason not to do the later but it would make things easier.

I guess the rule for today is, if in doubt, pass your filenames through "expandFilename()".

Hope this helps,

- Melv.

#3 Thanxs Melv this "expandFilename" really was handly...