Specular map diffuse shader

//*****************************************************************************
// OSJ basic skin vertex shader
// Based on TSE procedural shader
// modified to correct for normal map issue   
//*****************************************************************************
//-----------------------------------------------------------------------------
// Structures                                                                  
//-----------------------------------------------------------------------------
struct VertData
{
   float2 texCoord        : TEXCOORD0;
   float3 T               : TEXCOORD2;
   float3 B               : TEXCOORD3;
   float3 N               : TEXCOORD4;
   float3 normal          : NORMAL;
   float4 position        : POSITION;
};


struct ConnectData
{
   float4 hpos            : POSITION;
   float2 outTexCoord     : TEXCOORD0;
   float4 outLightVec     : TEXCOORD2;
   float3 pos             : TEXCOORD3;
   float3 outEyePos       : TEXCOORD4;
};


//-----------------------------------------------------------------------------
// Main                                                                        
//-----------------------------------------------------------------------------
ConnectData main( VertData IN,
                  uniform float4x4 modelview       : register(C0),
                  uniform float3   inLightVec      : register(C24),
                  uniform float3   eyePos          : register(C20),
                  uniform float4x4 objTrans        : register(C12)
)
{
   ConnectData OUT;

   OUT.hpos = mul(modelview, IN.position);
   OUT.outTexCoord = IN.texCoord;

   float3x3 objToTangentSpace;
   objToTangentSpace[0] = IN.T;
   objToTangentSpace[1] = IN.B;
	//WORKAROUND  
	//this:
   objToTangentSpace[2] = IN.normal;
	//was originally (uncomment below and comment out above
	//to use this shader for interiors):
	//objToTangentSpace[2] = IN.N;
	//should be changed back after ms3 when IN.N is fixed for ts

   OUT.outLightVec.xyz = -inLightVec;
   OUT.outLightVec.xyz = mul(objToTangentSpace, OUT.outLightVec);
   OUT.pos = mul(objToTangentSpace, IN.position.xyz / 100.0);
   OUT.outEyePos.xyz = mul(objToTangentSpace, eyePos.xyz / 100.0);
   OUT.outLightVec.w = step( 0.0, dot( -inLightVec, IN.normal ) );

   return OUT;
}

//*****************************************************************************
// OSJ basic skin pixel shader
// Based on TSE procedural shader
// modifications:
//  specular map rgb used for specular color, 
//  spec alpha used for specular power (range 1-128)
//    black will not bring the specular to a power (ie spec^1),
//    white will bring spec^128
//  specular attenuation is still controlled by the diffuse color map alpha channel.
//    black will show no specular (fully attenuated), white will show full specular
//*****************************************************************************

//-----------------------------------------------------------------------------
// Structures                                                                  
//-----------------------------------------------------------------------------
struct ConnectData
{
   float2 texCoord        : TEXCOORD0;
   float4 lightVec        : TEXCOORD2;
   float3 pixPos          : TEXCOORD3;
   float3 eyePos          : TEXCOORD4;
};


struct Fragout
{
   float4 col : COLOR0;
};


//-----------------------------------------------------------------------------
// Main                                                                        
//-----------------------------------------------------------------------------
Fragout main( ConnectData IN,
              uniform sampler2D diffuseMap      : register(S0),
              uniform sampler2D bumpMap         : register(S1),
				  uniform sampler2D specMap			: register(S2),
              uniform float4    ambient         : register(C2)
)
{
   Fragout OUT;

   //Diffuse
   float4 diffuseColor = tex2D(diffuseMap, IN.texCoord);
   OUT.col = diffuseColor;
   
   //Bump
   float4 bumpNormal = tex2D(bumpMap, IN.texCoord);
   float4 bumpDot = saturate( dot(bumpNormal.xyz * 2.0 - 1.0, IN.lightVec.xyz) );
   OUT.col *= bumpDot + ambient;

   //Specular
   float3 eyeVec = normalize(IN.eyePos - IN.pixPos);
   float3 halfAng = normalize(eyeVec + IN.lightVec.xyz);
   float specular = 
	saturate( dot(bumpNormal.xyz * 2.0 - 1.0, halfAng) ) * IN.lightVec.w;
	
	//SpecMap-->
	//get data from the specular map
	float4 specColor = tex2D(specMap, IN.texCoord);
	//tighten edge of specular based on power defined by the specMap alpha channel
	//scale and offset for 1-128 scale
	specular = pow(specular, (specColor.a * 127) +1);
	//change '127' to change the overall range
	//blend in and attenuate according to the diffuse color alpha
	//exhange the above specColor.a with the below diffuseColor.a
	//if you want to use the channels differently
	//or possibly use bumpNormal.a for either if you want to 
	//use the normal map alpha channel
   OUT.col += specColor * specular * diffuseColor.a;
	//SpecMap<--
	
   return OUT;
}