Object Tweening

Initially, I wanted to create a new C++ class to handle positional tweening in T2D. Basically, it would be an object that would know how to perform various types of motion (quadratic easing, sinusoidal easing, etc), and would also keep track of all the necessary information about the object being tweened and the individual steps in the tween itself.

Then I started looking at the T2D source and realized I had no idea where to start :)

So I started to think about how I might do this with TorqueScript, and came up with some handy functions to animate an objects motion. These are based on the tweening functions in Robert Penner's "Programming Macromedia Flash MX"... I'm no math guy :)

Linear Tween

function linearTween(%startX, %startY, %changeX, %changeY, %duration, %obj) {
    %timeStep = 1;
    %duration = %duration / 5;
    while (%timeStep <= %duration) {
        %x = %changeX * %timeStep  / %duration + %startX;
        %y = %changeY * %timeStep  / %duration + %startY;
        %obj.schedule((5 * %timeStep), setPosition, (%x SPC %y));
        %timeStep++;
    }    
}

Using linearTween() -

// get the current x and y position of the object we want to tween
%x = getWord(%objectToTween.getPosition(), 0);
%y = getWord(%objectToTween.getPosition(), 1);

// create our tween, moving our object 20 units right
// and 6 units down over a duration of 2 seconds (2000 ms)

linearTween(%x, %y, 20, 6, 2000, %objectToTween);

Quadratic Ease-out

function easeOutQuad(%startX, %startY, %changeX, %changeY, %duration, %obj) {

    %timeStep = 1;
    %duration = %duration / 5;

    while (%timeStep <= %duration) {
        %timeStepNormal = %timeStep/%duration;
        %x = -(%changeX) * (%timeStepNormal) * (%timeStepNormal - 2) + %startX;
        %y = -(%changeY) * (%timeStepNormal) * (%timeStepNormal - 2) + %startY;
        %obj.schedule((5 * %timeStep), setPosition, (%x SPC %y));
        %timeStep ++;
    }    

}

Using quadratic ease out is the same as linear tween -

// get the current x and y position of the object we want to tween
%x = getWord(%objectToTween.getPosition(), 0);
%y = getWord(%objectToTween.getPosition(), 1);

// create our tween, moving our object 20 units right
// and 6 units down over a duration of 2 seconds (2000 ms)

easeOutQuad(%x, %y, 20, 6, 2000, %objectToTween);

These aren't optimized in any kind of way, and if any one knows of a better way to do it, please let me know :)

I hope these are at least of some use to people. If so, I might post up a few others (cubic easing, circular easing etc)

Thanks,
Chris

[edit]Fixed the loop as suggested by Matt[/edit]