Clips for guns (with animations)

Mathmatics

I got the idea for this resouce from www.garagegames.com/community/resources/view/2225
First, to start off, go to your weapon of choice .cs file, I'll be using the RocketLauncher.cs file.
Go to your weapon image for that weapon and add in the following.

usesclip = true;
   ammoInClip = 3;
   clipSize = 3;
   reloadSec = 2.3;
   reloadType = "Clip";

you can add this anywhere before the state names for the animations. Next go to your script/server folder and scroll down to the Weapon.cs. Then go to the WeaponImage::onMount and change it to

function WeaponImage::onMount(%this, %obj, %slot)
{
   // Images assume a false ammo state on load.  We need to
   // set the state according to the current inventory.
   if(%this.ammo !$= "")
   {
      if(%this.usesclip == false)
      {
      if (%obj.getInventory(%this.ammo))
      {
         %obj.setImageAmmo(%slot, true);
         %currentAmmo = %obj.getInventory(%this.ammo);
      }
      else
         %currentAmmo = 0;
      %obj.client.RefreshWeaponHud(%currentAmmo, %this.item.previewImage, %this.item.reticle);
      }
      else{
         if(%obj.getInventory(%this.ammo) || %this.ammoInClip > 0)
         {
            %currentAmmo = %obj.getInventory(%this.ammo);
            %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%currentAmmo, %this.item.previewImage, 
            %this.item.reticle);
            if(%this.ammoInClip <= 0)
            {
               %this.reload(%obj, %slot, %this.clipSize, %this.reloadSec, %this.reloadType);
            }
            else{
               %obj.setImageAmmo(%slot, true);
            }
         }
      }
   }
}

This will have it check to see if the weapon has a clip or not. All I added was to see if it needed to reload, if it does, it will call the reload function, which we will add next. For this to work we need two functions. One to do all the math of the reloading, and one to tell the game you have reloaded. Add this to the end of the same file.

function WeaponImage::reload(%this, %obj, %slot, %bulletsLeft, %time, %reloadType)
{
   %obj.setImageAmmo(%slot, false);
   if(%obj.getInventory(%this.ammo) <= 0)//no Ammo left
   {
      %obj.setImageAmmo(%slot, false);
      return;
   }
   
   if(%bulletsLeft == 0)//see if there are no bullets to reload, if so stop the reload process
   {
      %obj.setImageAmmo(%slot, true);
      return;
   }
      
   if(%reloadType $= "Clip")//Clip type
   {
      if(((%obj.getInventory(%this.ammo)) - %bulletsLeft) >= 0)//see if we have enough bullets
      {
      %obj.decInventory(%this.ammo,%bulletsLeft);//if so decrease the ammount we need
      %this.ammoInClip = %bulletsLeft;// set it to the number of bullets we needed
      %bulletsLeft -= %bulletsLeft;//set bullets left to zero
      //ready to go
      }
      else{//if not then put bullets in until where out
         %bulletsLeft = %obj.getInventory(%this.ammo);
         %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%obj.getInventory(%this.ammo), 
         %this.item.previewImage, %this.item.reticle);
         %obj.setImageAmmo(%slot, false);
         for (%i = 0; %i < %bulletsLeft; %i++)
         {
            %obj.decInventory(%this.ammo,1);//decrease the bullets by one
            %this.ammoInClip += 1;//give one to the clip and then repeat if we can still add more
         }
      }
      //schedule(%time * 1000, %obj, "setImageAmmo",%slot,true);//reload done, set ready
      echo(%time);
      %this.schedule(%time*1000, "onReloadDone",%obj,%slot);
      
      %obj.setImageAmmo(%slot, false);
   }
}
function WeaponImage::onReloadDone(%this,%obj, %slot)
{
   %obj.setImageAmmo(%slot, true);
   %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%obj.getInventory(%this.ammo), %this.item.previewImage, %this.item.reticle);
}

The reload function is fairly easy to figure out. First we set the gun to play its no ammo animation, Next, if it has no ammo left in the pile we jump out of the function so the gun will stay with no ammo, then we check the clip type, if its a full clip at a time, we reload all at once.We check to see if we have enough ammo to fill the clip, if so, we fill it up all the way, if not, we use a for loop to reload until were out of ammo. Then we schedual the reload done so the gun will be ready in the ammount of time you want it to reload for. Now, there is one last thing to change, and that is the onFire function.
Change it to this.

function WeaponImage::onFire(%this, %obj, %slot)
{
   //echo("c4WeaponImage::onFire( "@%this.getName()@", "@%obj.client.nameBase@", "@%slot@" )");

   // Decrement inventory ammo. The image's ammo state is updated
   // automatically by the ammo inventory hooks.
   if(%this.usesclip == false)
   {
   if ( !%this.infiniteAmmo )
   {
      %obj.decInventory(%this.ammo, 1);
      %currentAmmo =  %obj.getInventory(%this.ammo);
      %obj.client.RefreshWeaponHud(%currentAmmo, %this.item.previewImage, %this.item.reticle);
   }

   if (%this.projectileSpread)
   {
      // We'll need to "skew" this projectile a little bit.  We start by
      // getting the straight ahead aiming point of the gun
      %vec = %obj.getMuzzleVector(%slot);

      // Then we'll create a spread matrix by randomly generating x, y, and z
      // points in a circle
      for(%i = 0; %i < 3; %i++)
         %matrix = %matrix @ (getRandom() - 0.5) * 2 * 3.1415926 * %this.projectileSpread @ " ";
      %mat = MatrixCreateFromEuler(%matrix);

      // Which we'll use to alter the projectile's initial vector with
      %muzzleVector = MatrixMulVector(%mat, %vec);
   }
   else
   {
      // Weapon projectile doesn't have a spread factor so we fire it using
      // the straight ahead aiming point of the gun
      %muzzleVector = %obj.getMuzzleVector(%slot);
   }

   // Get the player's velocity, we'll then add it to that of the projectile
   %objectVelocity = %obj.getVelocity();
   %muzzleVelocity = VectorAdd(
      VectorScale(%muzzleVector, %this.projectile.muzzleVelocity),
      VectorScale(%objectVelocity, %this.projectile.velInheritFactor));

   // Create the projectile object
   %p = new (%this.projectileType)()
   {
      dataBlock = %this.projectile;
      initialVelocity = %muzzleVelocity;
      initialPosition = %obj.getMuzzlePoint(%slot);
      sourceObject = %obj;
      sourceSlot = %slot;
      client = %obj.client;
   };
   MissionCleanup.add(%p);

   // Do some recoil if this weapon has the required field:  recoilType
   if (%this.recoilType !$= "")
      CommandToClient(%obj.client, 'DoRecoil', %this.recoilType);

   return %p;
   }
   else{
      
      //%obj.decInventory(%this.ammo, 1);
      %currentAmmo =  %obj.getInventory(%this.ammo);
      %this.ammoInClip -= 1;
      %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%currentAmmo, %this.item.previewImage, 
      %this.item.reticle);
      if (%this.projectileSpread)
   {
      // We'll need to "skew" this projectile a little bit.  We start by
      // getting the straight ahead aiming point of the gun
      %vec = %obj.getMuzzleVector(%slot);

      // Then we'll create a spread matrix by randomly generating x, y, and z
      // points in a circle
      for(%i = 0; %i < 3; %i++)
         %matrix = %matrix @ (getRandom() - 0.5) * 2 * 3.1415926 * %this.projectileSpread @ " ";
      %mat = MatrixCreateFromEuler(%matrix);

      // Which we'll use to alter the projectile's initial vector with
      %muzzleVector = MatrixMulVector(%mat, %vec);
   }
   else
   {
      // Weapon projectile doesn't have a spread factor so we fire it using
      // the straight ahead aiming point of the gun
      %muzzleVector = %obj.getMuzzleVector(%slot);
   }

   // Get the player's velocity, we'll then add it to that of the projectile
   %objectVelocity = %obj.getVelocity();
   %muzzleVelocity = VectorAdd(
      VectorScale(%muzzleVector, %this.projectile.muzzleVelocity),
      VectorScale(%objectVelocity, %this.projectile.velInheritFactor));

   // Create the projectile object
   %p = new (%this.projectileType)()
   {
      dataBlock = %this.projectile;
      initialVelocity = %muzzleVelocity;
      initialPosition = %obj.getMuzzlePoint(%slot);
      sourceObject = %obj;
      sourceSlot = %slot;
      client = %obj.client;
   };
   MissionCleanup.add(%p);
   if(%this.ammoInClip <= 0)
      %this.reload(%obj, %slot, %this.clipSize, %this.reloadSec, %this.reloadType);
   // Do some recoil if this weapon has the required field:  recoilType
   if (%this.recoilType !$= "")
      CommandToClient(%obj.client, 'DoRecoil', %this.recoilType);

   return %p;
   }
}

All this basicly does is take ammo from the clip instead of the ammo pile and reload if were out of ammo.
The one last thing you should do is go into the GUI and change the length of the ammo text so its bigger.
There are two quick things that need to be changed, 1, in weapon.cs change

if ($weaponOrderIndex[%requestedSlot] !$= "" && %this.hasInventory($weaponOrderIndex[%requestedSlot]) && %this.hasAmmo($weaponOrderIndex[%requestedSlot]))

to

if (($weaponOrderIndex[%requestedSlot] !$= "" && %this.hasInventory($weaponOrderIndex[%requestedSlot]) && %this.hasAmmo($weaponOrderIndex[%requestedSlot])) || ($weaponOrderIndex[%requestedSlot] !$= "" && %this.hasInventory($weaponOrderIndex[%requestedSlot]) && %this.hasClip($weaponOrderIndex[%requestedSlot])))

finaly add

function ShapeBase::hasClip(%this,%weapon)
{
   return(%weapon.image.ammoInClip > 0);
}

to inventory.cs and thats all.

Animations

Alright, so now that we have all the mathmatics of the reloading down, lets add a reload animation. Unfortunetly, there is no function to make the gun animate unless we use states. So, to start, go to your NoAmmo state inside RocketLauncher.cs. Change the state to:

stateName[6] = "NoAmmo";
   stateScript[6] = "onNoAmmo";
   stateTransitionOnAmmo[6] = "ClipReload";
   stateSequence[6] = "NoAmmo";
   stateTransitionOnTriggerDown[6] = "DryFire";

next at the end of the file add

stateName[19] = "ClipReload";
   stateTransitionOnTimeout[19] = "Ready";
   stateTimeoutValue[19] = 5.3;
   stateAllowImageChange[19] = false;
   stateSequence[19] = "magReload";
   stateEjectShell[19] = false; // set to true to enable shell casing eject
   stateSound[19] = RocketLauncherReloadSound;

with the current code we have this will not work, so we have to modify it a little. Go to the WeaponImage::Reload and change it to

function WeaponImage::reload(%this, %obj, %slot, %bulletsLeft, %time, %reloadType)
{
   %obj.setImageAmmo(%slot, false);
   if(%obj.getInventory(%this.ammo) <= 0)//no Ammo left
   {
      %obj.setImageAmmo(%slot, false);
      return;
   }
   
   if(%bulletsLeft == 0)//see if there are no bullets to reload, if so stop the reload process
   {
      %obj.setImageAmmo(%slot, true);
      return;
   }
      
   if(%reloadType $= "Clip")//Clip type
   {
      if(((%obj.getInventory(%this.ammo)) - %bulletsLeft) >= 0)//see if we have enough bullets
      {
      %obj.decInventory(%this.ammo,%bulletsLeft);//if so decrease the ammount we need
      %this.ammoInClip = %bulletsLeft;// set it to the number of bullets we needed
      %bulletsLeft -= %bulletsLeft;//set bullets left to zero
      //ready to go
      }
      else{//if not then put bullets in until where out
         %bulletsLeft = %obj.getInventory(%this.ammo);
         %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%obj.getInventory(%this.ammo), 
         %this.item.previewImage, %this.item.reticle);
         %obj.setImageAmmo(%slot, false);
         for (%i = 0; %i < %bulletsLeft; %i++)
         {
            %obj.decInventory(%this.ammo,1);//decrease the bullets by one
            %this.ammoInClip += 1;//give one to the clip and then repeat if we can still add more
         }
      }
      %this.schedule(%time*1000, "onReloadDone",%obj,%slot);
      %this.schedule(%time*1000, "reloadPhase2",%obj,%slot);
      %obj.setImageAmmo(%slot, false);
      //no Longer have to wait to set ammo true, reload animation happens right after ammo is gotten
      
   }
}

now go to WeaponImage::onReloadDone and change it to

function WeaponImage::onReloadDone(%this,%obj, %slot)
{
   %obj.client.RefreshWeaponHud(%this.ammoInClip@"/"@%obj.getInventory(%this.ammo), %this.item.previewImage, %this.item.reticle);
}

then at the bottom of the file add

function WeaponImage::onNoAmmo(%this, %obj, %slot)
{
   if(%obj.getInventory(%this.ammo) <=0 && %this.ammoInClip == 0)
   {
      %obj.setImageAmmo(%slot, false);//no ammo
   }
}

function WeaponImage::reloadPhase2(%this,%obj,%slot)
{
   %obj.setImageAmmo(%slot, true);
}

now there is one last thing to do, in the RocketLauncher.cs find the reloadSec and change it to the transition time for the fire sequence(0.833).
Now, what does this all do, well first, when the No ammo is called, it waits until we have ammo. The reload function waits until the fire is complete and then tells the gun it has ammo, the gun then plays the reload clip animation then goes back to being ready. If there are any problems, comments, or suggestions, please post, I might have forgoten something. Thank you.