Tile Highlighting Based On Mouse Position

function t2dTileLayer::tilePosition(%this, %tile)
{
	%xOffset = %this.getPositionX() - (%this.getWidth() /2);
	%yOffset = %this.getPositionY() - (%this.getHeight()/2);
	%worldX = %xOffset +
			 (%this.getTileSizeX() * getWord(%tile, 0)) +
			 (%this.getTileSizeX() * 0.5);
	%worldY = %yOffset +
			 (%this.getTileSizeY() * getWord(%tile, 1)) +
			 (%this.getTileSizeY() * 0.5);

	return %worldX SPC %worldY;
}

function map::clear(%this)
{
	echo("clearing map");
	%mapWidth  = %this.getTileCountX();
	%mapHeight = %this.getTileCountY();

	for (%x = 0; %x < %mapWidth; %x++)
	{
		for (%y = 0; %y < %mapHeight; %y++)
			$map[%x, %y] = "";
	}
}

function map::initializeMap(%this)
{
	%this.clear();
}

function map::onLevelLoaded(%this, %scenegraph)
{
	%this.initializeMap();
}

function map::print(%this)
{
	%mapWidth  = %this.getTileCountX();
	%mapHeight = %this.getTileCountY();

	for (%y = 0; %y < %mapHeight; %y++)
	{
		%line = "";
		for (%x = 0; %x < %mapWidth; %x++)
			if (isObject($map[%x, %y]))
			{
				%line = %line @ " Y ";
				echo("found " @ $map[%x, %y].getName() @ " at " @ %x SPC %y);
			}
			else
				%line = %line @ " N ";
		echo(%line);
	}
}

function map::setTile(%this, %object, %tile)
{
	if (!("" $= %object.tileX))
	{
		$map[%object.tileX, %object.tileY] = "";
	}

	%object.tileX = getWord(%tile, 0);
	%object.tileY = getWord(%tile, 1);
	$map[%object.tileX, %object.tileY] = %object;
}

function map::hasValue(%this, %tile)
{
	%x = getWord(%tile, 0);
	%y = getWord(%tile, 1);
	return isObject($map[%x, %y]);
}

function map::highlightTile(%this, %tile, %red, %green, %blue, %alpha)
{
	//--- If they didn't pass in a color, use a default one
	if (%red==0 && %green==0 && %blue==0)
	{
		%red = 0; %green = 1; %blue = 1; %alpha = 0.5;
	}

	%highlight = new t2dStaticSprite() {
		Scenegraph = %this.getScenegraph();
		BlendColor = %red SPC %green SPC %blue SPC %alpha;
		ImageMap   = "squareImageMap";
		Layer      = "2";
		Position   = %this.tilePosition(%tile);
		Size       = %this.getTileSizeX() SPC %this.getTileSizeY();
	};

	//--- Save this so we can turn it off later
	$highlightMap[getWord(%tile, 0), getWord(%tile, 1)] = %highlight;
}

function map::clearHighlights(%this)
{
	%mapWidth  = map.getTileCountX();
	%mapHeight = map.getTileCountY();

	for (%x = 0; %x < %mapWidth; %x++)
	{
		for (%y = 0; %y < %mapHeight; %y++)
			%this.dehighlightTile(%x SPC %y);
	}
}

function map::dehighlightTile(%this, %tile)
{
	%object = $highlightMap[getWord(%tile, 0), getWord(%tile, 1)];
	if (isObject(%object))
	{
		%object.safeDelete();
		$highlightMap[getWord(%tile, 0), getWord(%tile, 1)] = "";
	}
}

function map::hasLineOfSight(%this, %start, %end)
{
	%result = Bresenham(%start, %end);

	%isBlocked = false;

	//--- Should probably ignore the first and last points.
	//--- If we're looking from us to someone else, both of those
	//---  points will be occupied
	//--- It's easier here to chop the points than at the caller's
	//---  end since he won't know what the first point to use would be
	%numPoints = %result.getCount() - 1;
	for (%i=1; %i < %numPoints; %i++)
	{
		%object = %result.getObject(%i);
		%point = %object.Point;
//		echo("Line crosses tile (" @ %point @ ")");

		if (%this.hasValue(%point))
		{
			%isBlocked = true;
			map.highlightTile(%Point, 1, 0, 0, 0.5);
		}
		else
			map.highlightTile(%Point, 0, 1, 0, 0.5);
	}

	echo("hasLineOfSight = " @ !%isBlocked);
	return !%isBlocked;
}

function Bresenham(%start, %end)
{
	%startX = getWord(%start, 0);
	%startY = getWord(%start, 1);
	%endX   = getWord(%end,   0);
	%endY   = getWord(%end,   1);

	//--- The algorithm only works in one direction
	//---  so if that's not, change our problem to match the solution :(
	//--- We're going to count along the long end so if the long end
	//---  isn't X we're gonna swap X and Y
	%isSteep = mAbs(%endY - %startY) > mAbs(%endX - %startX);
	if (%isSteep)
	{
		%t = %startX;
		%startX = %startY;
		%startY = %t;

		%t = %endX;
		%endX = %endY;
		%endY = %t;
	}

	//--- Force our line to go left to right
	if (%startX > %endX)
	{
		%t = %startX;
		%startX = %endX;
		%endX   = %t;
		%t = %startY;
		%startY = %endY;
		%endY   = %t;
	}

	%changeInX = %endX - %startX;
	%changeInY = mAbs(%endY - %startY);
	%error = 0;
	if (%startY < %endY)
		%yStep = 1;
	else
		%yStep = -1;

	%result = new SimSet();
	%y = %startY;
	for (%x = %startX; %x <= %endX; %x++)
	{
		%point = %x SPC %y;
		if (%isSteep)
		{
			%point = %y SPC %x;
		}
		//--- Using silly syntax because Codeweaver whines
		//---  when you define datablocks inside function calls
		%t = new SimObject() { Point = %point; };
		%result.add(%t);

		%error += %changeInY;
		if ((2*%error) >= %changeInX)
		{
			%y += %yStep;
			%error -= %changeinX;
		}
	}

	return %result;
}

function t2dTileMap::onTileScript (%this, %tilelayer, %tilepos, %tilescript)  
{  
    if ( %tilescript $= "OpenSpace" )
	{
		%newHighlighterOpen = HighlighterOpenTemplate.cloneWithBehaviors();
		%xTile = getWord( %tilepos, 0);
		%yTile = getWord( %tilepos, 1);
		%tileWorldPos = %tilelayer.getTileWorldPosition(%xTile, %yTile);
		%newHighlighterOpen.setPosition(%tileWorldPos);
	}
}  

function HighlighterOpen::OnMouseEnter(%this)
{
	%this.setLayer( 20 );
}

function HighlighterOpen::OnMouseLeave(%this)
{
	%this.setLayer( 31 );
}