Introduction: FreeBuild, phpBB2 integrations and SAX chat

Project Introduction

I suppose I might as well introduce my project at this time as well so that my screenshots make sense. I'm sure most people who've been around GarageGames long enough are familiar with Blockland. What most of you probably aren't familiar with is a lot of the drama surrounding the Blockland community. Long before Blockland released it's Retail version, a thriving modding community grew up around it. One of the mod development teams, TBM, made no bones about the fact that they intended to make their mod a better game than Eric Hartman's eventual Blockland Retail release, and a lot of resentment sprung up between TBM and the mainline Blockland community. When modders of from another "faction" stole code + artwork from TBM, the TBM developers at the time retaliated by including a script in TBM that would delete the stolen artwork from the other mod directories. Eric used this as an excuse to accuse TBM of planting a virus, and banned it's developers and players from the community. I began playing sometime later, when it was recommended to me by a friend, and put significant amounts of time into mapping and coding AI scripts for multiplayer games in TBM. Probably 6 months after this came an increasing desire in the TBM community to get out from under the shadow of tensions with the Blockland community and develop our own game. I joined the dev-team for a Lego-themed game based on the old TBM. Eventually this effort fell apart too, and I was left in control of the project. I spent a long time working with script only on the TGE 1.4 demo, until I saved up money this spring for a TGE 1.5 license and picked up a couple people to help with scripting and artwork. The project is now in full swing, and is titled "FreeBuild: The Builder's Game"

I'm hoping to making a beta release by the end of this semester, and I'll be posting about interesting new features as I finish them. In that light I'll begin (later this evening) with explaining the process I've gone through to integrate FreeBuild with the phpBB forum and MySQL powered SAX chat on the Cemetech programming+technology community of which I'm an administrator and which is home to this project.

phpBB2 and SAX Walkthrough: Part 1

In the development of FreeBuild I presented with an interesting dilemma. I wanted to allow users to have a central place to register their in-game nicknames, share builds, and chat as a cohesive community, but the game servers are user hosted, and not running on any sort of official dedicated box over which I would have any control. To this end I set up a 3-part system to handle the following tasks

• Registering servers with Cemetech (the central login database + chat location, serving as a stand-in Master Server).
• Allowing clients to log in to Cemetech for chatting, protecting their usernames
• Checking that clients connecting to servers are authenticated with Cemetech.

This is made more difficult by the fact that I don't want to just kick off anyone who isn't logged in, to allow for LAN situations or times when Cemetech is down. The system is still a little rough around the edges, and doesn't support all the features I'd like yet, but it's still worth giving the basic tour, since the solution will be different for anyone who's implementing it.

The first thing is the client login. I originally tried implementing this with TGE's built in HTTP and TCP objects, but it was way too slow, and fairly hard to work with. So I compiled in bank's libcurl integration, and modified it to the point that you see here.

Here are my base client-side login functions:

function trylogin(%username, %password, %autologin){
	%auth = new SimCurl();
	%auth.setUrl("http://www.cemetech.net/scripts/torqueauth.php?login");
	%auth.setCookieJar("core/client/cookies/auth.txt");
	%auth.addPostField("username",%username);
	%auth.addPostField("password",%password);
	if(%autologin) %auth.addPostField("autologin","1");
	%auth.setFinishCallback("handleLoginResponse");
	%auth.setFailedCallback("handleLoginFailure");
	%auth.setProgressCallback("handleLoginProgress");
	$Pref::Player::SID = "";
	echo("Logging in...");
	%auth.start();
}


function handleLoginResponse(%auth){
	while(!%auth.isEOF()){
		%line = %auth.readLine();
		if(getword(%line, 0) $=  "LOGIN:"){
			%line = restwords(%line);
			$pref::Player::SID = getword(%line, 0);
			$pref::Player::Name = restwords(%line);
			echo("Logged in successfully");
		} else{
			echo(%line);
		}
	}
	%auth.delete();
}

function handleLoginFailure(%auth){
	echo("Could not login. Status follows: " @ %auth.getStatus());
	%auth.delete();
}

function handleLoginProgress(%auth){
	%total = %auth.getSizeTotal();
	%now = %auth.getSizeNow();
	if(%total) echo("Logging in:" @ ((%now/%total)*100) @ "%");
	else echo("Logging in: progress unknown");
	
	//-^ save this for a gui
}



function checksession(){
	%auth = new SimCurl();
	%auth.setUrl("http://www.cemetech.net/scripts/torqueauth.php?sid="@$pref::player::sid);
	%auth.loadCookieFile("core/client/cookies/auth.txt");
	%auth.setCookieJar("core/client/cookies/auth.txt");
	%auth.addPostField("check_session","1");
	%auth.setFinishCallback("handleLoginResponse");
	%auth.setFailedCallback("handleLoginFailure");
	%auth.setProgressCallback("handleLoginProgress");
	$Pref::Player::SID = "";
	echo("Logging in...");
	%auth.start();
}

function handleLogoutResponse(%auth){
	while(!%auth.isEOF()){
		%line = %auth.readLine();
		if(getword(%line, 0) $=  "LOGOUT:"){
			$pref::Player::SID = "";
			echo("Logged out successfully");
		} else{
			echo(%line);
		}
	}
	%auth.delete();
}

function handleLogoutFailure(%auth){
	echo("Could not logout. Status follows: " @ %auth.getStatus());
	%auth.delete();
}

function handleLogoutProgress(%auth){
	%total = %auth.getSizeTotal();
	%now = %auth.getSizeNow();
	if(%total) echo("Logging out:" @ ((%now/%total)*100) @ "%");
	else echo("Logging out: progress unknown");
}


function logout(){
	%auth = new SimCurl();
	%auth.setUrl("http://www.cemetech.net/scripts/torqueauth.php?logout&sid="@$pref::Player::SID);
	%auth.loadCookieFile("core/client/cookies/auth.txt");
	%auth.setCookieJar("core/client/cookies/auth.txt");
	%auth.setFinishCallback("handleLogoutResponse");
	%auth.setFailedCallback("handleLogoutFailure");
	%auth.setProgressCallback("handleLogoutProgress");
	echo("Logging out...");
	%auth.start();
}

There are 3 critical functions here.
trylogin(), checksession() and logout(), and some important things to note. trylogin() sets the cookie jar for reading cookies, but doesn't try to send any. SID is stored in the cookie, but more importantly, this saves the data necessary for autologin to behave correctly under phpBB2. checksession() is used to refresh the SID upon opening FreeBuild, but is only called if the autologin $pref::* variable is set. You'll notice that checksession() uses the same callbacks as trylogin(), this is because we want it to have the same effect. If the stored SID is still valid, or there's any valid auto-login data in the stored cookies, Cemetech will return exactly the same info as if you were logging in the for the first time. If you don't have any valid session hanging around, the old session data is destroyed so that the engine knows you aren't logged in. Finally, it's important to note that if logging out fails (due to server downtime, temporary database issues, whatever), that the logout() callbacks do not destroy the session data. This is so that the users are aware that their session and autologin keys are most probably still valid in the database which in turn will hopefully encourage them to try to log out again (and protect their account from compromise) instead of leaving sessions open. This is the account-safety equivalent of protecting against memory leaks by calling delete on an object before you set pointers to it to null.

All this is well and good, but the system above is still entirely console based, and unhelpful to most endusers. The next step is adding an interface to allow the users to interact with this. I created a 2-tabbed interface in my main menu, pictured here.

In reality this is a hidden 3-tab system, where the contents of the Cemetech On tab are replaced depending on whether or not you are logged in. The Cemetech Off tab disables logging in (and server registration) for LAN play, or falling back to use of the GarageGames master server in case of an outage at Cemetech.

I also added a small dialog with a progress bar to show the progress of logging in + out operations. I next added a second code file that ties the login/checksession/logout functions and their callbacks to the gui system.

package loginOverrides{
	
	function trylogin(%username, %password, %autologin){
		canvas.pushDialog(LoginProgressGui);
		LoginProgressBar.setValue(0);
		Parent::trylogin(%username, %password, %autologin);
	}
	
	function checksession(){
		canvas.pushDialog(LoginProgressGui);
		LoginProgressBar.setValue(0);
		Parent::checksession();
	}
	
	
	function handleLoginResponse(%auth){
		%loginfail = 1;
		%loginstatus = "";
		while(!%auth.isEOF()){
			%line = %auth.readLine();
			if(getword(%line, 0) $=  "LOGIN:"){
				%line = restwords(%line);
				$pref::Player::SID = getword(%line, 0);
				$pref::Player::Name = restwords(%line);
				LoginProgressText.setText("Logged in successfully");
				LoginProgressBar.setValue(100);
				%loginfail = 0;
			} else if(getword(%line, 0) $= "ERROR:"){
				%loginstatus = %line;
			}
		}
		%auth.delete();
		Canvas.popDialog(LoginProgressGui);
		if(%loginfail){
			$pref::player::sid = "";
			messageboxok("Error Logging In...", %loginstatus);
		} else{
			toggleCemetech(1);
		}
	}
	
	function handleLoginFailure(%auth){
		%auth.delete();
		Canvas.popDialog(LoginProgressGui);
		$pref::player::sid = "";
		messageboxok("Error Logging In...", %auth.getStatus());
	}
	
	function handleLoginProgress(%auth){
		%total = %auth.getSizeTotal();
		%now = %auth.getSizeNow();
		
		if(%total){
			LoginProgressText.setText("Logging In:" @ ((%now/%total)*100) @ "%");
			LoginProgressBar.setValue(mFloor((%now/%total)*100));
		}
		else{
			LoginProgressText.setText("Logging In: progress unknown");
			LoginProgressBar.setValue(0);
		}
	}
	
	function logout(){		
		canvas.pushDialog(LoginProgressGui);
		LoginProgressBar.setValue(0);
		Parent::logout();
	}
	
	
	function handleLogoutResponse(%auth){
		%logoutfailure = 1;
		%logoutstatus = "";
		while(!%auth.isEOF()){
			%line = %auth.readLine();
			if(getword(%line, 0) $=  "LOGOUT:"){
				$pref::Player::SID = "";
				LoginProgressBar.setValue(100);
				%logoutfailure = 0;
			} else if(getword(%line, 0) $= "ERROR:"){
				%logoutstatus = %line;
			}
		}
		%auth.delete();
		Canvas.popDialog(LoginProgressGui);
		if(%logoutfailure){
			messageboxok("Error Logging Out...", %logoutstatus);
		} else{
			toggleCemetech($pref::CemetechOn);
		}
	}
	
	function handleLogoutFailure(%auth){
		LoginProgressText.setText("Could not logout.");
		LoginProgressBar.setValue(100);
		Canvas.popDialog(LoginProgressGui);
		%auth.delete();
		messageboxok("Could not logout", "Status follows: " @ %auth.getStatus());
	}
	
	function handleLogoutProgress(%auth){
		%total = %auth.getSizeTotal();
		%now = %auth.getSizeNow();
		if(%total){
			LoginProgressText.setText("Logging out: " @ ((%now/%total)*100) @ "%");
			LoginProgressBar.setValue(mFloor((%now/%total)*100));
		} else{
			LoginProgressText.setText("Logging out: progress unknown");
			LoginProgressBar.setValue(0);
		}
	}
	
};

activatepackage(loginOverrides);


if($pref::player::autologin && $pref::player::sid !$= ""){
	checksession();
}

This is fairly self-explanatory, as it mirrors the previous bit of code, but adds in the necessary elements for interacting with the GUI. The call to toggleCemetech() makes sure the tabs are in a consistent state. Now we'll take a look at how SAX is implemented. Note that this has not yet been tied in to the gui, because I still need to figure out some formatting issues.

package sax{
	function saxsay(%what){
		%saxsay = new SimCurl();
		%saxsay.setUrl("http://www.cemetech.net/scripts/torqueauth.php?saxsay&sid=" @ $pref::player::sid @ "&what=" @ urlencode(%what));
		%saxsay.loadCookieFile("core/client/cookies/auth.txt");
		%saxsay.setCookieJar("core/client/cookies/auth.txt");
		%saxsay.setFinishCallback("onSaxPostResponse");
		%saxsay.setFailedCallback("onSaxPostFailed");
		%saxsay.setProgressCallback("onSaxPostProgress");
		%saxsay.start();
	}

	
	function onSaxPostProgress(%this)
	{
	}
	
	function onSaxPostFailed(%this)
	{
		messageboxok("Sax Error!", %this.getStatus());
		%this.delete();
	}

	function onSaxPostResponse(%this)
	{
		while(!%this.isEOF()){
			%line = %this.readLine();
			if(%line !$= "OK"){
				messageboxok("Sax Error!", %line);
			}
		}
		%this.delete();
	}

	function initSaxRead(){
		echo("Initializing SAX...");
		if(!$pref::sax::lastread){
			$pref::sax::lastread = 1;
		}
	}
	
	function onSaxReadProgress(%this){}
	function onSaxReadFailed(%this){
		messageboxok("Sax Error!", %this.getStatus());
		%this.delete();
	}
	
	function onSaxReadResponse(%this){
		//Cemetech sense in reverse chronological order
		//this makes our job a pain in the butt.
		%readin = "";
		%lineid = "";
		%who = "";
		%what = "";
		%timestamp = 0;
		%linetype = 0;
		%app = "";
		while(!%this.isEOF()){
			%line = %this.readLine();
			if(%readin $= "") %readin = %line;
			else %readin = %line NL %readin;
		}
		
		//split on \x1b
		for(%i = 0; %i < getRecordCount(%readin); %i++){
			%line = getRecord(%readin, %i);
			%lineid =	getDelimitedItem(%line, "\x1b", 0);
			%who = 		getDelimitedItem(%line, "\x1b", 1);
			%what = 	getDelimitedItem(%line, "\x1b", 2);
			%timestamp = 	getDelimitedItem(%line, "\x1b", 3);
			%linetype = 	getDelimitedItem(%line, "\x1b", 4);
			%app = 		getDelimitedItem(%line, "\x1b", 5);
			if(%linetype != 2){
				echo("(" @ %app @ ")" SPC %who SPC ":" SPC %what);
			} else{
				echo("(" @ %app @ ") ***" @ %who SPC %what );
			}
			if(%lineid > $pref::sax::lastread) $pref::sax::lastread = %lineid;
		}
	}
	
	function saxUpdate(){
		%saxread = new SimCurl();
		%saxread.setUrl("http://www.cemetech.net/scripts/saxpop.php?i=" @ $pref::sax::lastread);
		%saxread.loadCookieFile("core/client/cookies/auth.txt");
		%saxread.setCookieJar("core/client/cookies/auth.txt");
		%saxread.setFinishCallback("onSaxReadResponse");
		%saxread.setFailedCallback("onSaxReadFailed");
		%saxread.setProgressCallback("onSaxReadProgress");
		%saxread.start();
	}

};

activatePackage(sax);
initSaxRead();

Posting to SAX is fairly straight forward, reading is a bit more interesting.
$pref::sax::lastread stores the row number of the last line read. initSaxRead() just makes sure that if it hasn't been set yet, it's set to 1. SAX either returns the most current 30 lines (if $pref::sax::lastread is less than the row number of the 30th most recent message), or if it's more recent, however many messages have happened since the last read. Since SAX publishes messages in reverse chronological order (like a Facebook newsfeed), my read method firsts reads them in and builds a correctly ordered list. Each row has 6 fields, which may or may not be empty, and are delimited with an "\\x1b" character. This presents a problem, since TGE's string manipulation functions are largely limited to dealing with spaces, tabs and new lines, or "tokens." At first glance tokens seem like a good match, since you can set custom delimiters, but the problem is that nextToken uses a greedy algorithm which reads as many delimiting characters as it can until it runs into something else. This means that any empty fields are skipped over, and values end up getting assigned in the wrong place. To work around this, I implemented new Console functions, based on the same internal getUnit() functions that are used by getWord(), getField(), and getRecord(). I've released this as a resource here, and you'll see calls to getDelimitedItem() in my source.


That's it for now, and I'll try to cover the server side interactions and the contents of torqueauth.php when I polish them up a little bit.