Prototyping: RPG Style Damage Numbers

Download Code File

1/7/2008 - Added a deleteDamage() and schedule the emitters to get deleted 2.5 seconds after they are created.

1/16/2008 - Added links to screenshot and video.

For a quick look, you should be able to drop the attached file into a clean starter.rts kit.
Please keep in mind, this is NOT the best way to implement this feature, but is the quickest. This was ripped out of my original code and applied to the starter.fps.
1. Setting up the datablocks
Create a file in the server/scripts directory called damageText.cs. You will need to add two datablocks for each number.

datablock ParticleData(zeroText)
{
   textureName          = "~/data/particles/battleText/zero";
   // Move with the wind
   dragCoefficient      = 2.0;
   // Float up
   gravityCoefficient   = -0.1;
   // Last awhile
   lifetimeMS           = 2000;
   // Change from fully opaque to semi transparent over lifetime
   colors[0]            = "0.50 0.0 0.0 1.0";
   colors[1]            = "0.50 0.0 0.0 0.5";
   // Shrink to under half the size over lifetime
   sizes[0]             = 1.0;
   sizes[1]             = 0.4;
};
datablock ParticleEmitterData(zeroEmitter)
{
   thetaMin          = 180;
   thetaMax          = 180;
   particles         = zeroText;
   lifetimeMS        = 100;
   ejectionPeriodMS  = 500;
   periodVarianceMS  = 0;
};

The next blocks would be ParticleData(oneText) and ParticleEmitterData(oneEmitter) and so on. This is a bit of a pain to set up. I would like to have a single image that has all the numbers, but I think that is something for later.
The last thing you need to do with this file is to set the NodeData properties.

datablock ParticleEmitterNodeData(TextEmitterNodeData)
{
   timeMultiple   = 1;
   isLooping      = false;
};

If you are not familiar with particles... join the club. I still haven't found a great resource/tutorial. Admittedly, I have not had the time or motivation yet to look that hard.
I found these were the best settings for my game. Play around with them a bit! The ParticleEmitterData block should remain the same unless you know what you're doing. This make the particle fire only once. With my limited knowledge of the particle system, it was a pain to get that to work. Ok, got 0-9 blocks set up? Good!

2. Parsing
Make a server/scripts/damage.cs file.
To get the numbers to letters, I had to write a small function to parse the damage numbers. A lot of languages I know don't allow numbers as the first character. I suppose I could have swapped them and done Text1 and Emitter1 and save a little processing time. I might still do that later and change it here.

function numToText(%damage)
{
   // Loop through each character
   for(%i=0;%i <= strlen(%damage);%i++)
   {
      switch$(getSubStr(%damage,%i,1))
      {
         case "0":
            %damages = setWord(%damages,%i,"zero");
         case "1":
            %damages = setWord(%damages,%i,"one");
         case "2":
            %damages = setWord(%damages,%i,"two");
         case "3":
            %damages = setWord(%damages,%i,"three");
         case "4":
            %damages = setWord(%damages,%i,"four");
         case "5":
            %damages = setWord(%damages,%i,"five");
         case "6":
            %damages = setWord(%damages,%i,"six");
         case "7":
            %damages = setWord(%damages,%i,"seven");
         case "8":
            %damages = setWord(%damages,%i,"eight");
         case "9":
            %damages = setWord(%damages,%i,"nine");
      }
   }
   return %damages;
}

Just in case this isn't clear to everyone; if you pass in 60, it comes out "six zero." Simple enough right? Great, let's move on!

3. Emitting
Now we want to be able to actually use these particles. So let's make a showDamage function after the numToText function.

function showDamage(%object,%damage)
{
   // Give us the text for the datablocks
   %damages = numToText(%damage);
   // Loop through each word and display them
   for(%i = 0;%i<getWordCount(%damages);%i++)
   {
      %pDam = new ParticleEmitterNode()
               {
                 // Places it over the object and spaces the particles out (there has to be a better way)
                 position = setWord(setWord(%object.getTransform(),2,getWord(%object.getTransform(),2)+2),0,getWord(%object.getTransform(),0)+(%i*0.5));
                 rotation = "1 0 0 180";
                 scale = "1 1 1";
                 dataBlock = TextEmitterNodeData;
                 //choose the emitter
                 emitter = getWord(%damages,%i)@"Emitter";
                 velocity = 0.5;
               };
      //Throw off numbers
      %object.emitter[%i] = %pDam;
      // schedule the emitter to die in 2.5 seconds (just after the lifetime of it) This is definitely not the best way to do it... but it works.
      schedule(2500,"deleteDamage",%obj.emitter[%i]);
   }
}

function deleteDamage(%obj)
{
   %obj.delete();
}

4. Tying it together
In server/scripts/game.cs
In the onServerCreated function add

exec("./damage.cs");
   exec("./damageText.cs");

right after

...
   exec("./crossbow.cs");
   exec("./environment.cs");

I added the call to showDamage in the Armor::damage function. However, there are a few places you can add it. So something like:

function Armor::damage(%this, %obj, %sourceObject, %position, %damage, %damageType)
{
   if (%obj.getState() $= "Dead")
      return;
   %obj.applyDamage(%damage);
   showDamage(%obj,%damage);

And that's it. Chase Kork down and ram an arrow into him and wait for the smoke to clear. The numbers will not follow him as he moves but for my purposes (a turn based RPG) this wasn't necessary.

These are examples from my implementation of it.
Screenshot
Video